Now remove source/header files not enabled by extensions-patch flags.

svn path=/testing/; revision=239

4 files changed, 383 insertions, 4 deletions

diff --git a/media-video/vdr/ChangeLog b/media-video/vdr/ChangeLog
index 6f37730..d7ac54e 100644
--- a/media-video/vdr/ChangeLog
+++ b/media-video/vdr/ChangeLog
@@ -2,6 +2,9 @@
 # Copyright 1999-2007 Gentoo Foundation; Distributed under the GPL v2
 # $Header: $
 
+  30 Jun 2007; Matthias Schwarzott <zzam@gentoo.org> +vdr-1.4.7-r2.ebuild:
+  Now remove source/header files not enabled by extensions-patch flags.
+
   25 Jun 2007; Matthias Schwarzott <zzam@gentoo.org> vdr-1.4.7-r1.ebuild:
   Updated 1.4.7-r1 ebuild to extensions-patch v32.
 
diff --git a/media-video/vdr/Manifest b/media-video/vdr/Manifest
index 6189c69..006c21e 100644
--- a/media-video/vdr/Manifest
+++ b/media-video/vdr/Manifest
@@ -23,14 +23,18 @@ EBUILD vdr-1.4.7-r1.ebuild 8453 RMD160 50ddaff9af6bf4f10d46fc9ae1e3bf741b027fd3
 MD5 22ab59a6d871147846229d9d29a70731 vdr-1.4.7-r1.ebuild 8453
 RMD160 50ddaff9af6bf4f10d46fc9ae1e3bf741b027fd3 vdr-1.4.7-r1.ebuild 8453
 SHA256 10c49d536bd4821ae7aa1cc692fca17b32e884f16c2dd8716513fc8143e31a23 vdr-1.4.7-r1.ebuild 8453
+EBUILD vdr-1.4.7-r2.ebuild 8634 RMD160 2f316e5cbe7808f7352205d7321f6db7b4cb6843 SHA1 052359de801519e1bda1afd3de1b32709a0d4966 SHA256 2dc274f96eeccd5a94e9cc7c90953a002fd99b0bef6d18bfeb940b2811ecbde5
+MD5 75f52c90bd311e6ea87a9a15af345a16 vdr-1.4.7-r2.ebuild 8634
+RMD160 2f316e5cbe7808f7352205d7321f6db7b4cb6843 vdr-1.4.7-r2.ebuild 8634
+SHA256 2dc274f96eeccd5a94e9cc7c90953a002fd99b0bef6d18bfeb940b2811ecbde5 vdr-1.4.7-r2.ebuild 8634
 EBUILD vdr-1.4.7.ebuild 8181 RMD160 c0418af29c01587062cb9d741a64f3089bec0c7b SHA1 000c44840da3bf7e392924601d7ec170b25f9938 SHA256 f958d2a335c646b3ba25bd09b7f5a132003c416537191eb1a15c3a95a92f8231
 MD5 e03929c6ddf4bfefc259250968f3b38d vdr-1.4.7.ebuild 8181
 RMD160 c0418af29c01587062cb9d741a64f3089bec0c7b vdr-1.4.7.ebuild 8181
 SHA256 f958d2a335c646b3ba25bd09b7f5a132003c416537191eb1a15c3a95a92f8231 vdr-1.4.7.ebuild 8181
-MISC ChangeLog 2131 RMD160 5a3f6e5e61164ebc57f71cc4fa031fb6870c3cc1 SHA1 45df82f08a9e293707a5d8608bb2913e14dc941e SHA256 ba442c0c50732dbbb97df28865e137adaeaed30c06dca5886220d29f4c9c498b
-MD5 9935c0c1584f116e4d4a5a6abfe85179 ChangeLog 2131
-RMD160 5a3f6e5e61164ebc57f71cc4fa031fb6870c3cc1 ChangeLog 2131
-SHA256 ba442c0c50732dbbb97df28865e137adaeaed30c06dca5886220d29f4c9c498b ChangeLog 2131
+MISC ChangeLog 2279 RMD160 45e6fc6965124a92178e429bfa5fcbdfc56c8242 SHA1 7d09ee746af9b0f8e6da987559cb43d66541f0ee SHA256 0e8ff603edf919f9cb9105d73dbff89a1b53cb1a7560ce252f38185759972aad
+MD5 94293ddd03db93b8f2394f64fe4df3f4 ChangeLog 2279
+RMD160 45e6fc6965124a92178e429bfa5fcbdfc56c8242 ChangeLog 2279
+SHA256 0e8ff603edf919f9cb9105d73dbff89a1b53cb1a7560ce252f38185759972aad ChangeLog 2279
 MISC metadata.xml 257 RMD160 8bee49b98c59996aaaa019fb2c764c08d8004507 SHA1 d2419394e7d5c7463d7dea33e9190ebd57484531 SHA256 0dd45fbbaf1c6173535e371e3ff8a3faa41f3f89123ac9dffe338998599ebe26
 MD5 116de98355049ce943c3b6fedc00b4a3 metadata.xml 257
 RMD160 8bee49b98c59996aaaa019fb2c764c08d8004507 metadata.xml 257
@@ -44,3 +48,6 @@ SHA256 4ff3401cc6bdb2656682ef874b6e02e50d5e44dce9ae04699260c837b79b2984 files/di
 MD5 cef1c23ab322f01fe380f52c97b7800f files/digest-vdr-1.4.7-r1 506
 RMD160 35da6a2aef01521d519631749d398c62c9717ce3 files/digest-vdr-1.4.7-r1 506
 SHA256 fecb439d6d003a5b3ef570010f79379dec3fee3eb0dd7ea821440a157d7f2a01 files/digest-vdr-1.4.7-r1 506
+MD5 cef1c23ab322f01fe380f52c97b7800f files/digest-vdr-1.4.7-r2 506
+RMD160 35da6a2aef01521d519631749d398c62c9717ce3 files/digest-vdr-1.4.7-r2 506
+SHA256 fecb439d6d003a5b3ef570010f79379dec3fee3eb0dd7ea821440a157d7f2a01 files/digest-vdr-1.4.7-r2 506
diff --git a/media-video/vdr/files/digest-vdr-1.4.7-r2 b/media-video/vdr/files/digest-vdr-1.4.7-r2
new file mode 100644
index 0000000..1e76514
--- /dev/null
+++ b/media-video/vdr/files/digest-vdr-1.4.7-r2
@@ -0,0 +1,6 @@
+MD5 7888a22b1fa0c8bd7b5922c57c164cbe VDR-Extensions-Patch-32.tar.bz2 217019
+RMD160 43ec5662a51885589ecc37594b3806342b8e1698 VDR-Extensions-Patch-32.tar.bz2 217019
+SHA256 7d2caea7b47cc8eeb86b2539fea1dfeae1d0ec32d5162756f59c0ec6efb45ab1 VDR-Extensions-Patch-32.tar.bz2 217019
+MD5 81be33a0edb93288ca3d235a04107ec4 vdr-1.4.7.tar.bz2 560888
+RMD160 0e7a0d1cf133ee5e168afb6e2374e2ee6c229fcf vdr-1.4.7.tar.bz2 560888
+SHA256 9e9f3687efc135d890cf8d70068221e661fea21d1efd7d8dc74bc4e810d4a464 vdr-1.4.7.tar.bz2 560888
diff --git a/media-video/vdr/vdr-1.4.7-r2.ebuild b/media-video/vdr/vdr-1.4.7-r2.ebuild
new file mode 100644
index 0000000..2a46a64
--- /dev/null
+++ b/media-video/vdr/vdr-1.4.7-r2.ebuild
@@ -0,0 +1,363 @@
+# Copyright 1999-2007 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: /var/cvsroot/gentoo-x86/media-video/vdr/vdr-1.4.6.ebuild,v 1.1 2007/03/19 18:05:23 zzam Exp $
+
+inherit eutils flag-o-matic multilib
+
+IUSE_EXTENSIONS="cmdctrl cmdsubmenu cutterlimit cutterqueue cuttime ddepgentry
+	dolbyinrec dvbplayer dvbsetup dvdarchive dvdchapjump graphtft
+	jumpplay liemikuutio livebuffer lnbshare mainmenuhooks noepg osdmaxitems pinplugin
+	rotor settime setup sortrecords sourcecaps submenu
+	subtitles switchtimer timercmd timerinfo validinput wareagleicon yaepg
+	syncearly dvlfriendlyfnames dvlrecscriptaddon dvlvidprefer hardlinkcutter"
+
+IUSE="debug vanilla bigpatch ${IUSE_EXTENSIONS}"
+
+BIGPATCH_FLAGS="WAREAGLEICON CUTTERLIMIT CUTTERQUEUE CUTTIME SORTRECORDS DVDARCHIVE LIEMIKUUTIO JUMPPLAY DOLBYINREC"
+
+EXT_V="32"
+EXT_P=VDR-Extensions-Patch-${EXT_V}
+EXT_DIR=${WORKDIR}/${EXT_P}/
+# Set if != $PV
+#EXT_VDR_PV=1.5.3
+
+DESCRIPTION="Video Disk Recorder - turns a pc into a powerful set top box for DVB"
+HOMEPAGE="http://www.cadsoft.de/vdr/"
+SRC_URI="ftp://ftp.cadsoft.de/vdr/${P}.tar.bz2
+	http://www.zulu-entertainment.de/files/patches/${EXT_P}.tar.bz2"
+
+KEYWORDS="~amd64 ~ppc ~x86"
+SLOT="0"
+LICENSE="GPL-2"
+
+
+DEPEND="media-libs/jpeg
+	sys-apps/gawk
+	media-tv/linuxtv-dvb-headers
+	sys-libs/libcap
+	dev-util/unifdef"
+
+RDEPEND="${DEPEND}
+	dev-lang/perl
+	media-tv/vdrplugin-rebuild
+	>=media-tv/gentoo-vdr-scripts-0.3.5"
+
+# Relevant Pathes for vdr on gentoo
+DVB_DIR=/usr/include
+VDR_INCLUDE_DIR=/usr/include/vdr
+CONF_DIR=/etc/vdr
+CAP_FILE=${S}/capabilities.sh
+CAPS="# Capabilities of the vdr-executable for use by startscript etc."
+
+get_plugin_libdir() {
+	echo /usr/$(get_libdir)/vdr/plugins
+}
+
+pkg_setup() {
+	use debug && append-flags -g
+}
+
+add_cap() {
+	while [ "$1" ]; do
+		CAPS="${CAPS}\n$1=1"
+		shift
+	done
+}
+
+enable_patch() {
+	local patch
+	while [ "$1" ]; do
+		patch="$1"
+		echo "$patch = 1" >> Make.config
+		shift
+	done
+}
+
+extensions_add_make_conf()
+{
+	# copy all ifdef for extensions-patch to Make.config
+	sed -e '1,/need to touch the following:/d' \
+		-e '/ifdef DVBDIR/,/^$/d' \
+		Make.config.template >> Make.config
+}
+
+extensions_all_defines() {
+	# extract all possible settings for extensions-patch
+	sed -e '/^#\?[A-Z].*= 1/!d' -e 's/^#\?//' -e 's/ .*//' \
+		Make.config.template \
+		| sort \
+		| tr '[:upper:]' '[:lower:]'
+}
+
+extensions_all_defines_unset() {
+	# extract all possible settings for extensions-patch
+	# and convert them to -U... for unifdef
+	sed -e '/^#\?[A-Z].*= 1/!d' -e 's/^#\?/-UUSE_/' -e 's/ .*//' \
+		Make.config.template \
+		| tr '\n' ' '
+}
+
+do_unifdef() {
+	ebegin "Unifdef sources"
+	local mf="Makefile.get"
+	cat <<'EOT' > $mf
+include Makefile
+show_def:
+	@echo $(DEFINES)
+show_src_files:
+	@echo $(OBJS:%.o=%.c)
+EOT
+
+	local DEFINES=$(extensions_all_defines_unset)
+
+	local RAW_DEFINES=$(make -f "$mf" show_def)
+	local VDR_SRC_FILES=$(make -f "$mf" show_src_files)
+	rm "$mf"
+
+	local def
+	for def in $RAW_DEFINES; do
+		case "${def}" in
+			-DUSE*)
+				DEFINES="${DEFINES} ${def}"
+				;;
+		esac
+	done
+
+	local f
+	for f in *.c; do
+
+		# Removing the src files the Makefile does not use for compiling vdr
+		if ! has $f ${VDR_SRC_FILES}; then
+			rm -f ${f} ${f%.c}.h
+			continue
+		fi
+
+		unifdef ${DEFINES} "$f" > "tmp.$f"
+		mv "tmp.$f" "$f"
+	done
+	for f in *.h; do
+		unifdef ${DEFINES} "$f" > "tmp.$f"
+		mv "tmp.$f" "$f"
+	done
+	eend 0
+}
+
+src_unpack() {
+
+	unpack ${A}
+	cd ${S}
+
+	ebegin "Changing pathes for gentoo"
+
+	sed \
+	  -e 's-ConfigDirectory = VideoDirectory;-ConfigDirectory = CONFIGDIR;-' \
+	  -i vdr.c
+
+	cat > Make.config <<-EOT
+		#
+		# Generated by ebuild ${PF}
+		#
+		DVBDIR			= ${DVB_DIR}
+		PLUGINLIBDIR	= $(get_plugin_libdir)
+		CONFIGDIR		= ${CONF_DIR}
+
+		DEFINES			+= -DCONFIGDIR=\"\$(CONFIGDIR)\"
+
+	EOT
+	eend 0
+
+	if ! use vanilla; then
+
+		# changes to extensions-patch to be applicable to vdr-$PV
+		local LOCAL_EXT_CHANGES="${FILESDIR}/extensions-patch-${EXT_V}-vdr-${PV}.diff"
+		if [[ -f "${LOCAL_EXT_CHANGES}" ]]; then
+			cd "${EXT_DIR}"
+			epatch "${LOCAL_EXT_CHANGES}"
+		fi
+
+		cd "${S}"
+		epatch "${EXT_DIR}/${PN}-${EXT_VDR_PV:-${PV}}_extensions.diff"
+		#epatch "${FILESDIR}/${P}-gentoo-hardlinkcutter.diff"
+
+		epatch "${FILESDIR}/vdr-add-svdrp-down-0.1.diff"
+		add_cap CAP_SHUTDOWN_SVDRP
+
+		epatch "${FILESDIR}/vdr-set-dumpable.diff"
+
+		# This allows us to start even if some plugin does not exist
+		# or is not loadable.
+		enable_patch PLUGINMISSING
+
+		# Patch necessary for media-plugins/vdr-reelchannelscan
+		# it does not change anything when plugin is not used
+		enable_patch CHANNELSCAN
+
+		if use bigpatch; then
+			enable_patch ${BIGPATCH_FLAGS}
+		fi
+
+		if [[ -n ${VDR_MAINTAINER_MODE} ]]; then
+			einfo "Doing maintainer checks:"
+
+			# these patches we do not support
+			# (or have them already hard enabled)
+			local IGNORE_PATCHES="channelscan pluginapi pluginmissing"
+
+			extensions_all_defines > ${T}/new.IUSE
+			echo $IUSE_EXTENSIONS $IGNORE_PATCHES|tr ' ' '\n' |sort > ${T}/old.IUSE
+			local DIFFS=$(diff -u ${T}/old.IUSE ${T}/new.IUSE|grep '^[+-][^+-]')
+			if [[ -z ${DIFFS} ]]; then
+				einfo "IUSE_EXTENSIONS is up to date."
+			else
+				ewarn "IUSE differences!"
+				local diff
+				for diff in $DIFFS; do
+					ewarn "$diff"
+				done
+			fi
+		fi
+
+		ebegin "Enabling selected patches"
+		local flag
+		for flag in $IUSE_EXTENSIONS; do
+			FLAG_UP=$(echo $flag|tr '[:lower:]' '[:upper:]')
+			use $flag && enable_patch ${FLAG_UP}
+		done
+		eend 0
+
+		extensions_add_make_conf
+
+		ebegin "Make depend"
+		emake .dependencies >/dev/null
+		eend $? "make depend failed"
+
+		do_unifdef
+	fi
+
+	# apply local patches defined by variable VDR_LOCAL_PATCHES_DIR
+	if test -n "${VDR_LOCAL_PATCHES_DIR}"; then
+		local dir_tmp_var
+		local LOCALPATCHES_SUBDIR=${PV}
+		for dir_tmp_var in allversions-fallback ${PV%_p*} ${PV} ; do
+			if [[ -d ${VDR_LOCAL_PATCHES_DIR}/${dir_tmp_var} ]]; then
+				LOCALPATCHES_SUBDIR="${dir_tmp_var}"
+			fi
+		done
+
+		echo
+		if [[ ${LOCALPATCHES_SUBDIR} == ${PV} ]]; then
+			einfo "Applying local patches"
+		else
+			einfo "Applying local patches (Using subdirectory: ${LOCALPATCHES_SUBDIR})"
+		fi
+
+		for LOCALPATCH in ${VDR_LOCAL_PATCHES_DIR}/${LOCALPATCHES_SUBDIR}/*.{diff,patch}; do
+			test -f "${LOCALPATCH}" && epatch "${LOCALPATCH}"
+		done
+	fi
+
+	if [[ -n "${VDRSOURCE_DIR}" ]]; then
+		cp -r ${S} ${T}/source-tree
+	fi
+
+
+	if ! use vanilla; then
+		add_cap CAP_IRCTRL_RUNTIME_PARAM \
+			CAP_VFAT_RUNTIME_PARAM \
+			CAP_CHUID
+
+		echo -e ${CAPS} > ${CAP_FILE}
+	fi
+}
+
+src_install() {
+	exeinto /usr/bin
+	doexe vdr
+	doexe svdrpsend.pl
+
+	insinto ${VDR_INCLUDE_DIR}
+	doins *.h
+	doins Make.config
+
+	insinto ${VDR_INCLUDE_DIR}/libsi
+	doins libsi/*.h
+
+	keepdir ${CONF_DIR}/plugins
+	keepdir ${CONF_DIR}/themes
+
+	insinto ${CONF_DIR}
+	doins *.conf channels.conf.*
+
+	keepdir "$(get_plugin_libdir)"
+
+	doman vdr.1 vdr.5
+
+	dohtml *.html
+	dodoc MANUAL INSTALL README* HISTORY*
+	dodoc TODO-enAIO-rm CONTRIBUTORS
+	newdoc ${EXT_DIR}/README README.extensions-patch
+
+	insinto /usr/share/vdr
+	doins ${CAP_FILE}
+
+	if [[ -n "${VDRSOURCE_DIR}" ]]; then
+		einfo "Installing sources"
+		insinto ${VDRSOURCE_DIR}/${P}
+		doins -r ${T}/source-tree/*
+		keepdir ${VDRSOURCE_DIR}/${P}/PLUGINS/lib
+	fi
+
+	if use setup; then
+		insinto /usr/share/vdr/setup
+		doins ${S}/menu.c
+
+		insinto /etc/vdr/plugins/setup
+		newins ${FILESDIR}/vdr-setup-menu-0.2.3.xml vdr-menu.xml
+	fi
+	chown -R vdr:vdr ${D}/${CONF_DIR}
+}
+
+pkg_postinst() {
+	elog "It is a good idea to run vdrplugin-rebuild now"
+	if has_version "<media-video/vdr-1.3.36-r3"; then
+		ewarn "Upgrade Info:"
+		ewarn
+		ewarn "If you had used the use-flags lirc, rcu or vfat"
+		ewarn "then, you now have to enable the associated functionality"
+		ewarn "in /etc/conf.d/vdr"
+		ewarn
+		ewarn "vfat is now set with VFAT_FILENAMES."
+		ewarn "lirc/rcu are now set with IR_CTRL."
+		ebeep
+	fi
+
+	if use setup; then
+		if ! has_version media-plugins/vdr-setup || \
+			! egrep -q '^setup$' "${ROOT}/etc/conf.d/vdr.plugins"; then
+
+			echo
+			ewarn "You have compiled media-video/vdr with USE=\"setup\""
+			ewarn "It is very important to emerge media-plugins/vdr-setup now!"
+			ewarn "and you have to loaded it in /etc/conf.d/vdr.plugins"
+		fi
+	fi
+
+	local keysfound=0
+	local key
+	local warn_keys="JumpFwd JumpRew JumpFwdSlow JumpRewSlow"
+	local remote_file=${ROOT}/etc/vdr/remote.conf
+
+	if [[ -e ${remote_file} ]]; then
+		for key in ${warn_keys}; do
+			if grep -q -i "\.${key} " "${remote_file}"; then
+				keysfound=1
+				break
+			fi
+		done
+		if [[ ${keysfound} == 1 ]]; then
+			ewarn "Your /etc/vdr/remote.conf contains keys which are no longer usable"
+			ewarn "Please remove these keys or vdr will not start:"
+			ewarn "#  ${warn_keys}"
+		fi
+	fi
+}