(cat_pn): No reverse dep needs py2 support

Package-Manager: Portage-2.3.84, Repoman-2.3.20
Signed-off-by: Pacho Ramos <pacho@gentoo.org>

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-python/datashape/datashape-0.5.4-r1.ebuild b/dev-python/datashape/datashape-0.5.4-r1.ebuild
new file mode 100644
index 000000000000..ba87920acb00
--- /dev/null
+++ b/dev-python/datashape/datashape-0.5.4-r1.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_6 )
+
+inherit distutils-r1
+
+DESCRIPTION="Language defining a data description protocol"
+HOMEPAGE="https://github.com/blaze/datashape"
+SRC_URI="https://github.com/blaze/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/numpy-1.7[${PYTHON_USEDEP}]
+	>=dev-python/multipledispatch-0.4.7[${PYTHON_USEDEP}]
+	dev-python/python-dateutil[${PYTHON_USEDEP}]
+"
+DEPEND="
+	doc? ( ${RDEPEND} dev-python/sphinx[${PYTHON_USEDEP}] )
+	test? ( ${RDEPEND}
+		dev-python/mock[${PYTHON_USEDEP}]
+		dev-python/pytest[${PYTHON_USEDEP}]
+	)
+"
+
+python_prepare_all() {
+	# Prevent un-needed d'loading
+	sed -e "s/'sphinx.ext.intersphinx', //" -i docs/source/conf.py || die
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	use doc && emake -C docs html
+}
+
+python_test() {
+	py.test || die "Tests failed under ${EPYTHON}"
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/build/html/. )
+	distutils-r1_python_install_all
+}