dev-python/virtualenv: Bump to 20.0.18

Signed-off-by: Michał Górny <mgorny@gentoo.org>

2 files changed, 85 insertions, 0 deletions

diff --git a/dev-python/virtualenv/Manifest b/dev-python/virtualenv/Manifest
index ed0310a1254b..1f1e5542792d 100644
--- a/dev-python/virtualenv/Manifest
+++ b/dev-python/virtualenv/Manifest
@@ -1,2 +1,3 @@
 DIST virtualenv-16.0.0.tar.gz 1968312 BLAKE2B efc25f7c12335bb8619c3de125af3693d73afc5e7ff4edf1afa95227360ab4d0eb2ffb574b9bb36de26a2bda65b1f06009308fef48b12a81050bbc1f4ab852e9 SHA512 aed6eff9b85107072c321b37c1725987d474caf615734ab40d8d1fa60f2635be1a1919a47fbd211127e38cf1c4002548c778df29fc56d45a4570b31906c0ee54
 DIST virtualenv-16.7.9.tar.gz 5116740 BLAKE2B 10b77c4d74d3b1be60d567caf60b48274893777313d7151350df1d8a7d86d7cbd299c6c04734cbad134512e2ea05f5bc694648b6e9307019ffd9b91f7d0cdaf5 SHA512 d7379941e299c44beba30eaab68d5f1a6650f767b24f95d5e8abd05c1529dca4c1423113a41ff42690bb2b2bd4fe05c3e47a8fed4f9df0972188f6c77034436b
+DIST virtualenv-20.0.18.tar.gz 7982748 BLAKE2B f759ff1c42aaf9229e3f8dedd7b50df12e3a7616f979e18a5a91d58afd190beea86c67e0f7c530ba327427f3a4967ab27d7b922723c9ce92cba844946f8eb8ff SHA512 9295acb4d21da13c93fcf2a73244137a6fd8384313cf2685b67295f3be8cf33aaf6d22fc9ba4fa93dbfd81429eeaf4eb46d752fb717f0f74c172a754b92d41e6
diff --git a/dev-python/virtualenv/virtualenv-20.0.18.ebuild b/dev-python/virtualenv/virtualenv-20.0.18.ebuild
new file mode 100644
index 000000000000..8ff9d70c19ca
--- /dev/null
+++ b/dev-python/virtualenv/virtualenv-20.0.18.ebuild
@@ -0,0 +1,84 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python{2_7,3_{6,7,8}} pypy3 )
+DISTUTILS_USE_SETUPTOOLS=manual
+
+inherit distutils-r1
+
+DESCRIPTION="Virtual Python Environment builder"
+HOMEPAGE="
+	https://virtualenv.pypa.io/en/stable/
+	https://pypi.org/project/virtualenv/
+	https://github.com/pypa/virtualenv/
+"
+SRC_URI="https://github.com/pypa/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+KEYWORDS="~amd64 ~x86"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-python/appdirs-1.4.3[${PYTHON_USEDEP}]
+	>=dev-python/distlib-0.3.0[${PYTHON_USEDEP}]
+	>=dev-python/filelock-3[${PYTHON_USEDEP}]
+	>=dev-python/setuptools-41[${PYTHON_USEDEP}]
+	>=dev-python/six-1.9.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/contextlib2-0.6.0[${PYTHON_USEDEP}]
+		>=dev-python/pathlib2-2.3.3[${PYTHON_USEDEP}]
+	' -2)
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_metadata-0.12[${PYTHON_USEDEP}]
+	' -2 python3_{6,7} pypy3)
+	$(python_gen_cond_dep '
+		>=dev-python/importlib_resources-1.0[${PYTHON_USEDEP}]
+	' -2 python3_6 pypy3)"
+# coverage is used somehow magically in virtualenv, maybe it actually
+# tests something useful
+BDEPEND="${RDEPEND}
+	test? (
+		dev-python/coverage[${PYTHON_USEDEP}]
+		>=dev-python/pip-20.0.2[${PYTHON_USEDEP}]
+		>=dev-python/pytest-mock-2.0.0[${PYTHON_USEDEP}]
+		>=dev-python/pytest-timeout-1.3.4[${PYTHON_USEDEP}]
+		dev-python/wheel[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/packaging-20.0[${PYTHON_USEDEP}]
+		' -3)
+	)"
+
+distutils_enable_sphinx docs \
+	dev-python/sphinx_rtd_theme \
+	dev-python/towncrier
+distutils_enable_tests pytest
+
+src_prepare() {
+	# we don't have xonsh
+	rm tests/unit/activation/test_xonsh.py || die
+	# TODO: investigate
+	sed -e 's:test_cross_major:_&:' \
+		-i tests/unit/create/test_creator.py || die
+
+	distutils-r1_src_prepare
+}
+
+src_configure() {
+	export SETUPTOOLS_SCM_PRETEND_VERSION=${PV}
+}
+
+python_test() {
+	# TODO: fix/skip with more granularity tests on pypy3
+	if has "${EPYTHON}" pypy3 python2.7; then
+		einfo "Skipping broken tests on pypy3"
+		continue
+	fi
+
+	distutils_install_for_testing
+
+	pytest -vv || die "Tests fail with ${EPYTHON}"
+}