dev-libs/sway: rc1 bump

Package-Manager: Portage-2.3.51, Repoman-2.3.12
Signed-off-by: Matthew Thode <prometheanfire@gentoo.org>

4 files changed, 139 insertions, 35 deletions

diff --git a/dev-libs/sway/Manifest b/dev-libs/sway/Manifest
index 35d0fe60c62a..8c229cddf4f3 100644
--- a/dev-libs/sway/Manifest
+++ b/dev-libs/sway/Manifest
@@ -1,3 +1,4 @@
 DIST sway-0.15.2.tar.gz 5398956 BLAKE2B 6bb527e802b7837ef39cb1e29597d55fd33831231dbfb7f12225e50c38e49ae17d8bf2eb43672c195c6e074986d254b1680bac7c9d60b80b84feaf07e09718df SHA512 c457ace514f5c69ebd366d313cce93a76b199bb51c7540debc9c0586bff490401e6374f9725c784474afdfcca15bcab686a972c6c178117e45e2de83825ed370
 DIST sway-1.0_beta1.tar.gz 5444424 BLAKE2B b2803b6770ac3fbb3c21b892a208008e60780b6002e983e6d144d4f97e04992d3a3e5589abe36042221d67a107e31f5e76ae193cbf3e36c71fcf027095140944 SHA512 745b16be7641446c54e1b8777be1f8a26e8275f7826590f594bf4a2001a6de42e394b602e1ccd26a1e8ebe256fde6f9b393f5560a1dd0a610867819076645c69
 DIST sway-1.0_beta2.tar.gz 5454362 BLAKE2B 2cb7f3042a53879c962e7204917765b4a7a2e90f2a6a7eb6bbb63383e31d7526e71ad7ac4edd708c47a31f3166f70c1633719c9cddf5b751327da79b523d6780 SHA512 532acb6f1510578b7d9d222f04ff8104c836428ef215ddb6d7181839231d65101b3d47c8389a38f14cf59692116495b60759062ebd797edf83cf77aebaac379f
+DIST sway-1.0_rc1.tar.gz 5461910 BLAKE2B a9b3a14dfbb40a616b58fce896f0088dfc722e942129e12e7dae3f2121cb84ffcd565902ee49712275e01d6b6a344642d85d8cf394a35b151725dcc94d19b40d SHA512 6532bae679774fcdb1bcc3044740ff5c56f5f6a007a08e910f4d9ee43ac0488be7666a87106b493923432f975088c90ff47369fa1a01c5e1cb67d3a1f9b74bce
diff --git a/dev-libs/sway/metadata.xml b/dev-libs/sway/metadata.xml
index cb1a5f1eeef6..c3ed1aa40733 100644
--- a/dev-libs/sway/metadata.xml
+++ b/dev-libs/sway/metadata.xml
@@ -26,6 +26,7 @@
 		something else.
 	</longdescription>
 	<use>
+		<flag name="clipboard">Install 'wl-clipboard': clipboard management</flag>
 		<flag name="elogind">Enable support for rootless session via elogind</flag>
 		<flag name="filecaps">Use Linux capability SYS_CAP_ADMIN rather than set*id for sway binary</flag>
 		<flag name="fish-completion">Enable fish completion support</flag>
diff --git a/dev-libs/sway/sway-1.0_rc1.ebuild b/dev-libs/sway/sway-1.0_rc1.ebuild
new file mode 100644
index 000000000000..95621d2f0721
--- /dev/null
+++ b/dev-libs/sway/sway-1.0_rc1.ebuild
@@ -0,0 +1,100 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit eutils fcaps meson
+
+DESCRIPTION="i3-compatible Wayland window manager"
+HOMEPAGE="https://swaywm.org"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/swaywm/sway.git"
+else
+	MY_PV=${PV/_rc/-rc}
+	SRC_URI="https://github.com/swaywm/sway/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+fi
+
+LICENSE="MIT"
+SLOT="0"
+IUSE="bash-completion clipboard doc elogind fish-completion +swaybar +swaybg +swayidle +swaylock +swaymsg +swaynag systemd +tray wallpapers X zsh-completion"
+REQUIRED_USE="?? ( elogind systemd )"
+
+RDEPEND="
+	>=dev-libs/wlroots-0.3[elogind=,systemd=,X=]
+	>=dev-libs/json-c-0.13:0=
+	>=dev-libs/libinput-1.6.0:0=
+	dev-libs/libpcre
+	dev-libs/wayland
+	>=dev-libs/wayland-protocols-1.14
+	x11-libs/cairo
+	x11-libs/libxkbcommon
+	x11-libs/pango
+	x11-libs/pixman
+	sys-libs/libcap
+	clipboard? ( dev-libs/wl-clipboard )
+	elogind? ( >=sys-auth/elogind-239 )
+	swaybar? ( x11-libs/gdk-pixbuf:2[jpeg] )
+	swaybg? ( x11-libs/gdk-pixbuf:2[jpeg] )
+	swayidle? ( dev-libs/swayidle )
+	swaylock? ( dev-libs/swaylock )
+	systemd? ( >=sys-apps/systemd-239 )
+	tray? ( >=sys-apps/dbus-1.10 )
+	X? ( x11-libs/libxcb:0= )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-libs/wayland-protocols
+	doc? ( >=app-text/scdoc-1.8.1 )
+	virtual/pkgconfig"
+
+FILECAPS=( cap_sys_admin usr/bin/sway )
+
+src_prepare() {
+	default
+
+	use swaybar || sed -e "s/subdir('swaybar')//g" -i meson.build || die
+	use swaybg || sed -e "s/subdir('swaybg')//g" -i meson.build || die
+	use swaymsg || sed -e "s/subdir('swaymsg')//g" -e "/swaymsg.[0-9].scd/d" \
+		-e "/completions\/[a-z]\+\/_\?swaymsg/d" -i meson.build || die
+	use swaynag || sed -e "s/subdir('swaynag')//g" -e "/swaynag.[0-9].scd/d" \
+		-e "/completions\/[a-z]\+\/_\?swaynag/d" -i meson.build || die
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use bash-completion bash-completions)
+		$(meson_use fish-completion fish-completions)
+		$(meson_use wallpapers default-wallpaper)
+		$(meson_use zsh-completion zsh-completions)
+		"-Dtray=$(usex tray enabled disabled)"
+		"-Dxwayland=$(usex X enabled disabled)"
+		"-Dwerror=false"
+	)
+	if use swaybar || use swaybg; then
+		emesonargs+=("-Dgdk-pixbuf=enabled")
+	else
+		emesonargs+=("-Dgdk-pixbuf=disabled")
+	fi
+	if [[ ${PV} != 9999 ]]; then
+		emesonargs+=("-Dsway-version=${PV}")
+	fi
+
+	meson_src_configure
+}
+
+pkg_postinst() {
+	elog "You must be in the input group to allow sway to access input devices!"
+	local dbus_cmd=""
+	if use tray; then
+		dbus_cmd="dbus-launch --sh-syntax --exit-with-session "
+	fi
+	if ! use systemd && ! use elogind; then
+		fcaps_pkg_postinst
+		elog ""
+		elog "If you use ConsoleKit2, remember to launch sway using:"
+		elog "exec ck-launch-session ${dbus_cmd}sway"
+	fi
+}
diff --git a/dev-libs/sway/sway-9999.ebuild b/dev-libs/sway/sway-9999.ebuild
index 14be762b4b73..95621d2f0721 100644
--- a/dev-libs/sway/sway-9999.ebuild
+++ b/dev-libs/sway/sway-9999.ebuild
@@ -1,30 +1,30 @@
-# Copyright 1999-2018 Gentoo Authors
+# Copyright 1999-2019 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
 
-if [[ ${PV} == 9999 ]] ; then
-		EGIT_REPO_URI="https://github.com/swaywm/sway.git"
-		inherit git-r3
-else
-		# Version format: major.minor-beta.betanum
-		SWAY_PV="$(ver_cut 1-2)-$(ver_cut 3).$(ver_cut 4)"
-		SRC_URI="https://github.com/swaywm/sway/archive/${SWAY_PV}.tar.gz -> ${P}.tar.gz"
-		S="${WORKDIR}/sway-${SWAY_PV}"
-		KEYWORDS="~amd64 ~x86"
-fi
-
 inherit eutils fcaps meson
 
 DESCRIPTION="i3-compatible Wayland window manager"
 HOMEPAGE="https://swaywm.org"
 
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/swaywm/sway.git"
+else
+	MY_PV=${PV/_rc/-rc}
+	SRC_URI="https://github.com/swaywm/sway/archive/${MY_PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+	S="${WORKDIR}/${PN}-${MY_PV}"
+fi
+
 LICENSE="MIT"
 SLOT="0"
-IUSE="elogind fish-completion +pam +swaybar +swaybg +swayidle +swaylock +swaymsg +swaynag systemd +tray wallpapers X zsh-completion"
+IUSE="bash-completion clipboard doc elogind fish-completion +swaybar +swaybg +swayidle +swaylock +swaymsg +swaynag systemd +tray wallpapers X zsh-completion"
 REQUIRED_USE="?? ( elogind systemd )"
 
-RDEPEND="~dev-libs/wlroots-9999[systemd=,elogind=,X=]
+RDEPEND="
+	>=dev-libs/wlroots-0.3[elogind=,systemd=,X=]
 	>=dev-libs/json-c-0.13:0=
 	>=dev-libs/libinput-1.6.0:0=
 	dev-libs/libpcre
@@ -34,18 +34,20 @@ RDEPEND="~dev-libs/wlroots-9999[systemd=,elogind=,X=]
 	x11-libs/libxkbcommon
 	x11-libs/pango
 	x11-libs/pixman
-	elogind? ( >=sys-auth/elogind-237 )
+	sys-libs/libcap
+	clipboard? ( dev-libs/wl-clipboard )
+	elogind? ( >=sys-auth/elogind-239 )
 	swaybar? ( x11-libs/gdk-pixbuf:2[jpeg] )
 	swaybg? ( x11-libs/gdk-pixbuf:2[jpeg] )
-	swaylock? (
-		pam? ( virtual/pam )
-		x11-libs/gdk-pixbuf:2[jpeg]
-	)
-	systemd? ( >=sys-apps/systemd-237 )
+	swayidle? ( dev-libs/swayidle )
+	swaylock? ( dev-libs/swaylock )
+	systemd? ( >=sys-apps/systemd-239 )
 	tray? ( >=sys-apps/dbus-1.10 )
 	X? ( x11-libs/libxcb:0= )"
 DEPEND="${RDEPEND}"
-BDEPEND="app-text/scdoc
+BDEPEND="
+	dev-libs/wayland-protocols
+	doc? ( >=app-text/scdoc-1.8.1 )
 	virtual/pkgconfig"
 
 FILECAPS=( cap_sys_admin usr/bin/sway )
@@ -55,10 +57,6 @@ src_prepare() {
 
 	use swaybar || sed -e "s/subdir('swaybar')//g" -i meson.build || die
 	use swaybg || sed -e "s/subdir('swaybg')//g" -i meson.build || die
-	use swayidle || sed -e "s/subdir('swayidle')//g" -e "/swayidle.[0-9].scd/d" \
-		-e "/completions\/[a-z]\+\/_\?swayidle/d" -i meson.build || die
-	use swaylock || sed -e "s/subdir('swaylock')//g" -e "/swaylock.[0-9].scd/d" \
-		-e "/completions\/[a-z]\+\/_\?swaylock/d" -i meson.build || die
 	use swaymsg || sed -e "s/subdir('swaymsg')//g" -e "/swaymsg.[0-9].scd/d" \
 		-e "/completions\/[a-z]\+\/_\?swaymsg/d" -i meson.build || die
 	use swaynag || sed -e "s/subdir('swaynag')//g" -e "/swaynag.[0-9].scd/d" \
@@ -67,13 +65,22 @@ src_prepare() {
 
 src_configure() {
 	local emesonargs=(
+		$(meson_use bash-completion bash-completions)
+		$(meson_use fish-completion fish-completions)
 		$(meson_use wallpapers default-wallpaper)
 		$(meson_use zsh-completion zsh-completions)
-		$(meson_use fish-completion fish-completions)
-		$(meson_use X enable-xwayland)
-		"-Dbash-completions=true"
+		"-Dtray=$(usex tray enabled disabled)"
+		"-Dxwayland=$(usex X enabled disabled)"
 		"-Dwerror=false"
 	)
+	if use swaybar || use swaybg; then
+		emesonargs+=("-Dgdk-pixbuf=enabled")
+	else
+		emesonargs+=("-Dgdk-pixbuf=disabled")
+	fi
+	if [[ ${PV} != 9999 ]]; then
+		emesonargs+=("-Dsway-version=${PV}")
+	fi
 
 	meson_src_configure
 }
@@ -81,18 +88,13 @@ src_configure() {
 pkg_postinst() {
 	elog "You must be in the input group to allow sway to access input devices!"
 	local dbus_cmd=""
-	if use tray ; then
-		elog ""
-		optfeature "experimental xembed tray icons support" kde-plasma/xembed-sni-proxy
+	if use tray; then
 		dbus_cmd="dbus-launch --sh-syntax --exit-with-session "
 	fi
-	if ! use systemd && ! use elogind ; then
+	if ! use systemd && ! use elogind; then
 		fcaps_pkg_postinst
 		elog ""
 		elog "If you use ConsoleKit2, remember to launch sway using:"
 		elog "exec ck-launch-session ${dbus_cmd}sway"
 	fi
-	if use swaylock && ! use pam; then
-		fcaps cap_sys_admin usr/bin/swaylock
-	fi
 }