sys-kernel/gentoo-kernel-bin: bump to 5.10.54-r1 for arm64

Signed-off-by: Sam James <sam@gentoo.org>

2 files changed, 114 insertions, 0 deletions

diff --git a/sys-kernel/gentoo-kernel-bin/Manifest b/sys-kernel/gentoo-kernel-bin/Manifest
index c300d7f7a5e3..c8e4002e423f 100644
--- a/sys-kernel/gentoo-kernel-bin/Manifest
+++ b/sys-kernel/gentoo-kernel-bin/Manifest
@@ -25,6 +25,7 @@ DIST gentoo-kernel-5.10.53-1.amd64.xpak 65475491 BLAKE2B 0697c8449ac103de265c28b
 DIST gentoo-kernel-5.10.53-1.arm64.xpak 61215071 BLAKE2B 8a912d6167bd64d8194973f50e3298ed125a5fa8396d3e7a23749cbb8daa2433c490f819971c783a9291ab19eec306b79db6494907936cabaebfc5ca725859b9 SHA512 872b3bfa2e1d5d61eca2ed228c79122b6b7e9bb4cc00f6be2d46ad6fd5c2aa6534a26a6e7763ad3605bbfc3fd572f1d3636b7baf8c10da0652d707a0749aa870
 DIST gentoo-kernel-5.10.53-1.x86.xpak 57218618 BLAKE2B b4948e9bd942e78d079607f4cc9611dae32b78ad2fa60245466e9b556433fb58db2c5c2709d2cb85762176c9fbbe26aeaa7dfae1cac2b7f8bdb10dc4ec243701 SHA512 6c2aaa43dfb99e28059333e43f3756b1405fa76847c19a0b7f52ed71328cb52541c66c1fb3335947e303f0c4c739d32b44598f56616a63fc0e1d8fd4a05dfb6e
 DIST gentoo-kernel-5.10.54-1.amd64.xpak 65489821 BLAKE2B 7503ee8e4620649fbc27779bc11ab92844172ff9a871c4d9f95a905a2220a8598ec957911b87935f473b694130898f3933c2898d3b6f1883a814a24d68940524 SHA512 c5e2f2362fe4934a8181b25f6bda8f2014e5aef17e5148301d72cb543356f51a857fd01231fe6a712132b42ba2b466aa65707dd8d82444d8f1c15d0abcb2413c
+DIST gentoo-kernel-5.10.54-1.arm64.xpak 61166026 BLAKE2B d86c315412edb45b9a8d4261e604db47102acfcfa94af6390855e3ca6a90959004c6958db2022a08d30f1fee35a8bb05f2c82af713433ed6e39d397163eed496 SHA512 cfd0c4eb028ee59c6e72d113387a7ec882c1c758e516cdd3e15d7f02530da9fcad96a686e3ecfa8bb23b02ec0bfec5ae889704b3885bc9fceb922ea9f90d936f
 DIST gentoo-kernel-5.10.54-1.x86.xpak 57217543 BLAKE2B e978d64011c71d186980da394914f0b2933a8154a64298c034337692ac0cf2d2093ded84a7ed574d239b3f176b951508a5ae4c248d5ab5fcce31a01f4f4c2c9c SHA512 c565daf009ccb06dc3b528e3e070464d17451c0d326b9354d103a0d97e679ef102c329da27165f050748c5813dd9bf7b3bee29e86824e97723b06d10d2f958ae
 DIST gentoo-kernel-5.12.19-1.amd64.xpak 66346655 BLAKE2B a03cbcdcd1a90d48d7e11e988d03efa43980f4d5d8af4b74e4c81f195faa01803af45fb38f7dc1f5af7e9b5338a53bc6f34837c37f7e853c088ec6c1dc084e44 SHA512 3d7f78c488ecee2532f8a8ad61e3aa0f5e238e4cd520d29288715a3dc5c488670d7378f3dc5bc110252dff10108dfbda27a54722c6b044151999428d002b34e1
 DIST gentoo-kernel-5.12.19-1.arm64.xpak 60043529 BLAKE2B 8746081847a39e1847b8e9f35fcd68565370b116d6418edf803c4cdca9d750ac8ada58c4a7fd377480a1c75b3c805864d419c02ee21675bc77ac195731385a18 SHA512 d1a8a9210a1ab3d3c1894be1fe524e64b859b0a02763feacfed1a24655540ade6c28af751b23e924fcc04fb9abd56e84c43d634ad80bbb4d5de79ed533b5ea50
diff --git a/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.54-r1.ebuild b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.54-r1.ebuild
new file mode 100644
index 000000000000..9f8ae493e215
--- /dev/null
+++ b/sys-kernel/gentoo-kernel-bin/gentoo-kernel-bin-5.10.54-r1.ebuild
@@ -0,0 +1,113 @@
+# Copyright 2020-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit kernel-install toolchain-funcs
+
+MY_P=linux-${PV%.*}
+GENPATCHES_P=genpatches-${PV%.*}-$(( ${PV##*.} + 6 ))
+BINPKG=${P/-bin/}-1
+
+DESCRIPTION="Pre-built Linux kernel with genpatches"
+HOMEPAGE="https://www.kernel.org/"
+SRC_URI+="
+	https://cdn.kernel.org/pub/linux/kernel/v$(ver_cut 1).x/${MY_P}.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.base.tar.xz
+	https://dev.gentoo.org/~mpagano/dist/genpatches/${GENPATCHES_P}.extras.tar.xz
+	arm64? (
+		https://dev.gentoo.org/~sam/binpkg/arm64/kernel/sys-kernel/gentoo-kernel/${BINPKG}.xpak
+			-> ${BINPKG}.arm64.xpak
+	)"
+S=${WORKDIR}
+
+LICENSE="GPL-2"
+KEYWORDS="~arm64"
+
+RDEPEND="
+	!sys-kernel/gentoo-kernel:${SLOT}"
+PDEPEND="
+	>=virtual/dist-kernel-${PV}"
+BDEPEND="
+	sys-devel/bc
+	sys-devel/flex
+	virtual/libelf
+	virtual/yacc"
+
+QA_PREBUILT='*'
+
+KV_LOCALVERSION='-gentoo-dist'
+KPV=${PV}${KV_LOCALVERSION}
+
+src_unpack() {
+	default
+	ebegin "Unpacking ${BINPKG}.${ARCH}.xpak"
+	tar -x < <(xz -c -d --single-stream "${DISTDIR}/${BINPKG}.${ARCH}.xpak")
+	eend ${?} || die "Unpacking ${BINPKG} failed"
+}
+
+src_prepare() {
+	local PATCHES=(
+		# meh, genpatches have no directory
+		"${WORKDIR}"/*.patch
+	)
+	cd "${MY_P}" || die
+	default
+}
+
+src_configure() {
+	# force ld.bfd if we can find it easily
+	local LD="$(tc-getLD)"
+	if type -P "${LD}.bfd" &>/dev/null; then
+		LD+=.bfd
+	fi
+
+	tc-export_build_env
+	local makeargs=(
+		V=1
+
+		HOSTCC="$(tc-getBUILD_CC)"
+		HOSTCXX="$(tc-getBUILD_CXX)"
+		HOSTCFLAGS="${BUILD_CFLAGS}"
+		HOSTLDFLAGS="${BUILD_LDFLAGS}"
+
+		CROSS_COMPILE=${CHOST}-
+		AS="$(tc-getAS)"
+		CC="$(tc-getCC)"
+		LD="${LD}"
+		AR="$(tc-getAR)"
+		NM="$(tc-getNM)"
+		STRIP=":"
+		OBJCOPY="$(tc-getOBJCOPY)"
+		OBJDUMP="$(tc-getOBJDUMP)"
+
+		# we need to pass it to override colliding Gentoo envvar
+		ARCH=$(tc-arch-kernel)
+
+		O="${WORKDIR}"/modprep
+	)
+
+	mkdir modprep || die
+	cp "usr/src/linux-${KPV}/.config" modprep/ || die
+	emake -C "${MY_P}" "${makeargs[@]}" modules_prepare
+}
+
+src_test() {
+	kernel-install_test "${KPV}" \
+		"${WORKDIR}/usr/src/linux-${KPV}/$(dist-kernel_get_image_path)" \
+		"lib/modules/${KPV}"
+}
+
+src_install() {
+	mv lib usr "${ED}"/ || die
+
+	# strip out-of-source build stuffs from modprep
+	# and then copy built files
+	find modprep -type f '(' \
+			-name Makefile -o \
+			-name '*.[ao]' -o \
+			'(' -name '.*' -a -not -name '.config' ')' \
+		')' -delete || die
+	rm modprep/source || die
+	cp -p -R modprep/. "${ED}/usr/src/linux-${KPV}"/ || die
+}