app-emulation/winetricks: version bump to 20190310

Package-Manager: Portage-2.3.62, Repoman-2.3.12
Signed-off-by: Jimi Huotari <chiitoo@gentoo.org>
Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

2 files changed, 87 insertions, 0 deletions

diff --git a/app-emulation/winetricks/Manifest b/app-emulation/winetricks/Manifest
index 396906c2f456..2853543d83e2 100644
--- a/app-emulation/winetricks/Manifest
+++ b/app-emulation/winetricks/Manifest
@@ -1,3 +1,4 @@
 DIST winetricks-20170823.tar.gz 639027 BLAKE2B ce0de22ff3363bd6fd675d07ea235ed5fb03ea7a84b3242329c094d6a9190c61813a1f360e74ece49d43d2dbf48dbbb1e94c4febc6e1a0d84cf1df895b0be6f9 SHA512 edc805be1a1c4fa64ae16b14fdd46786e259b88a0cde7afdf24bf934fa79f4acf3d9e599727fa589f155ec265569953b9e419cda79d54057157cbb1510261e3a
 DIST winetricks-20181203.tar.gz 671138 BLAKE2B 4a6f7154509bdd4c0ec73da8b94e44f80ca732f3e3e6c85149676df4eebfe586bcc1ffafffd4937e7d3b5efe6bde015bfc8ba53a1489d553001a9600c178b1bd SHA512 ff960b7830fd688315a6cef9c50f45435d95f4d8bb8feb5f3cab3c24302369b5876afdc8145d395be4b33c9d11c3606312aaf84cb675eeb511479c46490b1585
+DIST winetricks-20190310.tar.gz 673467 BLAKE2B b6c6a6d28e49f9b2745ac623f9a9d35bdcaa402c11b3f2055f3d2ef2d13ccff6adcda47261447aff7b70bfcd9bc65ea2a278368616df93f031fe212aa3201a5d SHA512 4f08228306a84cd2e1ecf0df46e951dfc5844716fadab903eca7ed09f15ed2bbba7ca5bf48384f934783be6a85b812129427a296a580561ee5b8483df0e64025
 DIST winetricks-gentoo-2012.11.24.tar.bz2 6398 BLAKE2B 54a4502f6e8ef15d21b02c43e3ce599e32d476c2559246064de14cc4ce2243ff11dde681d24c8a7f4913c3d7a10b855bda47e8fb8ecad31e00d839705416be6f SHA512 59c93b73f3a7b2d11aefcde2ff66659ff1de21ad4b5f232f4b60572f3a48b15a6c49f369b1696862bf1b33fde190bf5598945e9536fb41ddec42d8def4d2be2a
diff --git a/app-emulation/winetricks/winetricks-20190310.ebuild b/app-emulation/winetricks/winetricks-20190310.ebuild
new file mode 100644
index 000000000000..900a5b539221
--- /dev/null
+++ b/app-emulation/winetricks/winetricks-20190310.ebuild
@@ -0,0 +1,86 @@
+# Copyright 1999-2019 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit desktop xdg
+
+if [[ ${PV} == "99999999" ]] ; then
+	EGIT_REPO_URI="https://github.com/Winetricks/${PN}.git"
+	inherit git-r3
+	SRC_URI=""
+else
+	SRC_URI="https://github.com/Winetricks/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+wtg="winetricks-gentoo-2012.11.24"
+
+SRC_URI="${SRC_URI}
+	gtk? ( https://dev.gentoo.org/~chiitoo/distfiles/${wtg}.tar.bz2 )
+	kde? ( https://dev.gentoo.org/~chiitoo/distfiles/${wtg}.tar.bz2 )
+"
+
+DESCRIPTION="Easy way to install DLLs needed to work around problems in Wine"
+HOMEPAGE="https://github.com/Winetricks/winetricks https://wiki.winehq.org/Winetricks"
+
+LICENSE="LGPL-2.1+"
+SLOT="0"
+IUSE="gtk kde rar test"
+
+BDEPEND="
+	test? (
+		dev-python/bashate
+		dev-util/checkbashisms
+		dev-util/shellcheck
+	)
+"
+DEPEND=""
+RDEPEND="${DEPEND}
+	app-arch/cabextract
+	app-arch/p7zip
+	app-arch/unzip
+	net-misc/wget
+	virtual/wine
+	x11-misc/xdg-utils
+	gtk? ( gnome-extra/zenity )
+	kde? ( kde-apps/kdialog )
+	rar? ( app-arch/unrar )
+"
+
+# Test targets include syntax checks only, not the "heavy duty" tests
+# that would require a lot of disk space, as well as network access.
+
+# This uses a non-standard "Wine" category, which is provided by
+# '/etc/xdg/menus/applications-merged/wine.menu' from the
+# 'app-emulation/wine-desktop-common' package.
+# https://bugs.gentoo.org/451552
+QA_DESKTOP_FILE="usr/share/applications/winetricks.desktop"
+
+src_unpack() {
+	if [[ ${PV} == "99999999" ]]; then
+		git-r3_src_unpack
+
+		if use gtk || use kde; then
+			unpack ${wtg}.tar.bz2
+		fi
+
+	else
+		default
+	fi
+}
+
+src_test() {
+	./tests/shell-checks || die "Test(s) failed."
+}
+
+src_install() {
+	default
+
+	if use gtk || use kde; then
+		cd "${WORKDIR}/${wtg}" || die
+		domenu winetricks.desktop
+		insinto /usr/share/icons/hicolor/scalable/apps
+		doins wine-winetricks.svg
+	fi
+}