sys-apps/fwupd: Removed old.

Package-Manager: Portage-2.3.54, Repoman-2.3.12
Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

2 files changed, 0 insertions, 125 deletions

diff --git a/sys-apps/fwupd/Manifest b/sys-apps/fwupd/Manifest
index b354619f0e7a..ee20e104bcc0 100644
--- a/sys-apps/fwupd/Manifest
+++ b/sys-apps/fwupd/Manifest
@@ -1,3 +1,2 @@
-DIST fwupd-1.2.1.tar.gz 1754253 BLAKE2B 96938766758db32b00437e29c1b93870411687f7535102703faf4a09189dc4e90fd232794812d964895c12b0f63c86d0023ff1abcf9848059f04c12812158db9 SHA512 ce86c7b5e5c1a45a561f6fc195c3db861e29f9cd435df9e41a41ade94e2f9891508b0e32906df09fe074d383b5d7b6ac824201949f67e2c86c6c905eae550d78
 DIST fwupd-1.2.2.tar.gz 1768003 BLAKE2B 83d91761b7dc71296def8a88eb356df687906278ad6e351dffce246a1473de4a141e84e959dd4a785a36a846fc6884d4c83f512e8ea96d7f1b8f9c5dd438d784 SHA512 34221c905a75f4b6d9ee66bc08a2ceb0d65debb71771b8e0eeed26593dff4f29a4080b7c3164535e862f91f370bb519ae2761dc1f62c6b6de3c6c51ef5f0af65
 DIST fwupd-1.2.3.tar.gz 1768734 BLAKE2B 898f0cf3d86295840ad3f5a3736d9b0aedb61f678ca10d93bbbd9240513ae09a2d8941e3d6844024a20652eec487c7237dea5e6813d8d7c969d2998a970d23c1 SHA512 fc4fbb3778f9ed82eec4f05905d611f34344fccd78d199348b9f8ca83fedc48d1503fc77eb0b85026d77f5f83de5f609d97d0a0c008f3280b0a97e942000ba59
diff --git a/sys-apps/fwupd/fwupd-1.2.1.ebuild b/sys-apps/fwupd/fwupd-1.2.1.ebuild
deleted file mode 100644
index 7f9b147acd16..000000000000
--- a/sys-apps/fwupd/fwupd-1.2.1.ebuild
+++ /dev/null
@@ -1,124 +0,0 @@
-# Copyright 1999-2018 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=7
-
-PYTHON_COMPAT=( python3_{4,5,6,7} )
-
-inherit meson python-single-r1 vala xdg-utils
-
-DESCRIPTION="Aims to make updating firmware on Linux automatic, safe and reliable"
-HOMEPAGE="https://fwupd.org"
-SRC_URI="https://github.com/hughsie/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
-
-LICENSE="GPL-2+"
-
-SLOT="0"
-KEYWORDS="~amd64 ~x86"
-IUSE="colorhug dell doc +gpg +man nvme pkcs7 redfish systemd test thunderbolt uefi"
-REQUIRED_USE="
-	${PYTHON_REQUIRED_USE}
-	dell? ( uefi )
-"
-
-RDEPEND="
-	${PYTHON_DEPS}
-	app-arch/gcab
-	app-arch/libarchive:=
-	dev-db/sqlite
-	>=dev-libs/glib-2.45.8:2
-	dev-libs/json-glib
-	dev-libs/libgpg-error
-	dev-libs/libgudev:=
-	>=dev-libs/libgusb-0.2.9[introspection]
-	>=dev-libs/libxmlb-0.1.5
-	dev-python/pillow[${PYTHON_USEDEP}]
-	dev-python/pycairo[${PYTHON_USEDEP}]
-	dev-python/pygobject:3[cairo,${PYTHON_USEDEP}]
-	>=net-libs/libsoup-2.51.92:2.4[introspection]
-	>=sys-auth/polkit-0.103
-	virtual/libelf:0=
-	colorhug? ( >=x11-misc/colord-1.2.12:0= )
-	dell? (
-		sys-libs/efivar
-		>=sys-libs/libsmbios-2.4.0
-	)
-	gpg? (
-		app-crypt/gpgme
-		dev-libs/libgpg-error
-	)
-	nvme? ( sys-libs/efivar )
-	pkcs7? ( >=net-libs/gnutls-3.4.4.1:= )
-	redfish? (
-		sys-libs/efivar
-	)
-	systemd? ( >=sys-apps/systemd-211 )
-	!systemd? ( >=sys-auth/consolekit-1.0.0 )
-	thunderbolt? ( sys-apps/thunderbolt-software-user-space )
-	uefi? (
-		media-libs/fontconfig
-		media-libs/freetype
-		sys-boot/gnu-efi
-		>=sys-libs/efivar-33
-		x11-libs/cairo
-	)
-"
-DEPEND="
-	${RDEPEND}
-	$(vala_depend)
-	doc? ( dev-util/gtk-doc )
-	man? ( app-text/docbook-sgml-utils )
-	nvme? (	>=sys-kernel/linux-headers-4.4 )
-	test? ( net-libs/gnutls[tools] )
-"
-
-BDEPEND="
-	>=dev-util/meson-0.47.0
-	virtual/pkgconfig
-"
-
-# required for fwupd daemon to run.
-# NOT a build time dependency. The build system does not check for dbus.
-PDEPEND="sys-apps/dbus"
-
-src_prepare() {
-	default
-	sed -e "s/'--create'/'--absolute-name', '--create'/" \
-		-i data/tests/builder/meson.build || die
-	sed -e "/'-Werror',/d" \
-		-i plugins/uefi/efi/meson.build || die
-	vala_src_prepare
-}
-
-src_configure() {
-	xdg_environment_reset
-	local emesonargs=(
-		--localstatedir "${EPREFIX}"/var
-		-Dconsolekit="$(usex systemd false true)"
-		-Dgpg="$(usex gpg true false)"
-		-Dgtkdoc="$(usex doc true false)"
-		-Dman="$(usex man true false)"
-		-Dpkcs7="$(usex pkcs7 true false)"
-		-Dplugin_dell="$(usex dell true false)"
-		-Dplugin_nvme="$(usex nvme true false)"
-		-Dplugin_redfish="$(usex redfish true false)"
-		-Dplugin_synaptics="$(usex dell true false)"
-		-Dplugin_thunderbolt="$(usex thunderbolt true false)"
-		-Dplugin_uefi="$(usex uefi true false)"
-		-Dsystemd="$(usex systemd true false)"
-		-Dtests="$(usex test true false)"
-	)
-	meson_src_configure
-}
-
-src_install() {
-	meson_src_install
-	doinitd "${FILESDIR}"/${PN}
-}
-
-pkg_postinst() {
-	elog "In case you are using openrc as init system"
-	elog "and you're upgrading from <fwupd-1.1.0, you"
-	elog "need to start the fwupd daemon via the openrc"
-	elog "init script that comes with this package."
-}