kde-apps/kig: 20.12.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

2 files changed, 73 insertions, 0 deletions

diff --git a/kde-apps/kig/Manifest b/kde-apps/kig/Manifest
index 763ebac46c21..89e55bf1ce4a 100644
--- a/kde-apps/kig/Manifest
+++ b/kde-apps/kig/Manifest
@@ -1 +1,2 @@
 DIST kig-20.08.3.tar.xz 3467000 BLAKE2B 98b103707fa38c2d840a2b2c2fe3a9892e75fc0bd49367d514d33e1d04fef6379bce502d7f75bce29da13951ed79ee44e55700725506d81b220a624610ebae44 SHA512 becd24e67af434cda18ca7d483ace8649446273ca62eaf12618d5012bed1220e175de5841912075d67a54d777ff1a015a27d56ef53f12bb03c03d2c91e3bdf3f
+DIST kig-20.12.0.tar.xz 3122144 BLAKE2B 297a501d402a5149c50d0f85fcd9359ed2fd4cfaf20d24564c7829a1909136209869beb132ebef174ec763969271b1c80d6506e88e9450033ccadf8cc26fae30 SHA512 cdb0b166bbe09b9899849674171c183f9eec5dafb56a2c5236fe92a6a6cdaa7962b28d7352752c48cc1728d9ef7c9272d4afc6120cc2d45fafe75504320f1ea2
diff --git a/kde-apps/kig/kig-20.12.0.ebuild b/kde-apps/kig/kig-20.12.0.ebuild
new file mode 100644
index 000000000000..88c3ae6304dc
--- /dev/null
+++ b/kde-apps/kig/kig-20.12.0.ebuild
@@ -0,0 +1,72 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ECM_HANDBOOK="forceoptional"
+ECM_TEST="true"
+PYTHON_COMPAT=( python3_{7,8,9} )
+KFMIN=5.75.0
+QTMIN=5.15.1
+inherit python-single-r1 ecm kde.org
+
+DESCRIPTION="KDE Interactive Geometry tool"
+HOMEPAGE="https://apps.kde.org/en/kig https://edu.kde.org/kig/"
+
+LICENSE="GPL-2" # TODO: CHECK
+SLOT="5"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="geogebra scripting"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-qt/qtgui-${QTMIN}:5
+	>=dev-qt/qtprintsupport-${QTMIN}:5
+	>=dev-qt/qtsvg-${QTMIN}:5
+	>=dev-qt/qtwidgets-${QTMIN}:5
+	>=dev-qt/qtxml-${QTMIN}:5
+	>=kde-frameworks/karchive-${KFMIN}:5
+	>=kde-frameworks/kcompletion-${KFMIN}:5
+	>=kde-frameworks/kconfig-${KFMIN}:5
+	>=kde-frameworks/kconfigwidgets-${KFMIN}:5
+	>=kde-frameworks/kcoreaddons-${KFMIN}:5
+	>=kde-frameworks/kcrash-${KFMIN}:5
+	>=kde-frameworks/ki18n-${KFMIN}:5
+	>=kde-frameworks/kiconthemes-${KFMIN}:5
+	>=kde-frameworks/kparts-${KFMIN}:5
+	>=kde-frameworks/kservice-${KFMIN}:5
+	>=kde-frameworks/kwidgetsaddons-${KFMIN}:5
+	>=kde-frameworks/kxmlgui-${KFMIN}:5
+	geogebra? ( >=dev-qt/qtxmlpatterns-${QTMIN}:5 )
+	scripting? (
+		$(python_gen_cond_dep '
+			>=dev-libs/boost-1.70:=[python,${PYTHON_MULTI_USEDEP}]
+		')
+	)
+"
+DEPEND="${RDEPEND}
+	>=kde-frameworks/ktexteditor-${KFMIN}:5
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-20.08.70-cmake-boostpython.patch )
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+	ecm_pkg_setup
+}
+
+src_prepare() {
+	ecm_src_prepare
+	python_fix_shebang .
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DBOOSTPYTHON_VERSION_MAJOR_MINOR=${EPYTHON}
+		$(cmake_use_find_package geogebra Qt5XmlPatterns)
+		$(cmake_use_find_package scripting Boost)
+	)
+
+	ecm_src_configure
+}