dev-cpp/libjson-rpc-cpp: Bump to 1.1.0

2 files changed, 63 insertions, 0 deletions

diff --git a/dev-cpp/libjson-rpc-cpp/Manifest b/dev-cpp/libjson-rpc-cpp/Manifest
index 64fd99ea088d..29d36353b7ee 100644
--- a/dev-cpp/libjson-rpc-cpp/Manifest
+++ b/dev-cpp/libjson-rpc-cpp/Manifest
@@ -1 +1,2 @@
 DIST libjson-rpc-cpp-0.7.0.tar.gz 141665 BLAKE2B d52a5062fb16d2c356b1b6f8bd3576694bbaaf4908d3979c51e99ae31da2e503c90132674a43fcb1010ad3b5e04f839be6770225419879e5cf0f362f2b12ebf6 SHA512 f7547271040382cd2ac96a31eb81d891b016e4d0c33a3ba3e659c2de2e55136e7e243dd2d959c6d8a64ccba7ebd9f9e28070d710a6770c29f81c0750ffad9e3a
+DIST libjson-rpc-cpp-1.1.0.tar.gz 179442 BLAKE2B cfbfe703d1a3d4ccaf6d4d475a7c1686c8f7afc28b025d6fd3bfebdc41cff2b944e6600e68073c1b7e7c0a2463cbf6e9724cf618c5d481bf7a4600019b529922 SHA512 bf34eedb196b1e214292976036a00e933f8a9b4325441ea2e4ae049a7c818014a68dd9d2f22d01588f5e6d1e9f465c73a133b0fd8282f8cf78a05a493f4c461b
diff --git a/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-1.1.0.ebuild b/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-1.1.0.ebuild
new file mode 100644
index 000000000000..c43516bb1916
--- /dev/null
+++ b/dev-cpp/libjson-rpc-cpp/libjson-rpc-cpp-1.1.0.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit cmake-utils
+
+DESCRIPTION="JSON-RPC (1.0 & 2.0) framework for C++"
+HOMEPAGE="https://github.com/cinemast/libjson-rpc-cpp"
+SRC_URI="https://github.com/cinemast/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0/1"
+KEYWORDS="~amd64 ~x86"
+IUSE="doc +http-client +http-server redis-client redis-server +stubgen test"
+
+RDEPEND="
+	dev-libs/jsoncpp:=
+	http-client? ( net-misc/curl:= )
+	http-server? ( net-libs/libmicrohttpd:= )
+	redis-client? ( dev-libs/hiredis:= )
+	redis-server? ( dev-libs/hiredis:= )
+	stubgen? ( dev-libs/argtable:= )"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	test? ( dev-cpp/catch )"
+
+RESTRICT="!test? ( test )"
+
+src_configure() {
+	local mycmakeargs=(
+		-DHTTP_CLIENT=$(usex http-client)
+		-DHTTP_SERVER=$(usex http-server)
+		-DREDIS_CLIENT=$(usex redis-client)
+		-DREDIS_SERVER=$(usex redis-server)
+		# they are not installed
+		-DCOMPILE_EXAMPLES=OFF
+		-DCOMPILE_STUBGEN=$(usex stubgen)
+		-DCOMPILE_TESTS=$(usex test)
+		-DCATCH_INCLUDE_DIR="${EPREFIX}/usr/include/catch"
+	)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	cmake-utils_src_compile
+
+	use doc && emake -C "${BUILD_DIR}" doc
+}
+
+src_test() {
+	# Tests fail randomly when run in parallel
+	local MAKEOPTS=-j1
+	cmake-utils_src_test
+}
+
+src_install() {
+	cmake-utils_src_install
+
+	use doc && dodoc -r "${BUILD_DIR}"/doc/html
+}