app-admin/github-backup-utils: also install bm.sh in 2.7.0

It's a new file that didn't match their previous naming scheme. Without it,
running ghe-backup/restore fails:
$ ghe-backup
/usr/bin/../share/github-backup-utils/ghe-backup-config: line 26: /usr/share/github-backup-utils/bm.sh: No such file or directory

Package-Manager: portage-2.3.0

1 files changed, 49 insertions, 0 deletions

diff --git a/app-admin/github-backup-utils/github-backup-utils-2.7.0-r1.ebuild b/app-admin/github-backup-utils/github-backup-utils-2.7.0-r1.ebuild
new file mode 100644
index 000000000000..24304bc6198c
--- /dev/null
+++ b/app-admin/github-backup-utils/github-backup-utils-2.7.0-r1.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+# See https://github.com/github/backup-utils/issues/135
+PYTHON_COMPAT=(python2_7)
+inherit python-any-r1
+
+DESCRIPTION="Backup and recovery utilities for GitHub Enterprise"
+HOMEPAGE="https://github.com/github/backup-utils"
+SRC_URI="https://github.com/github/backup-utils/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64"
+IUSE="test"
+
+DEPEND="test? (
+	dev-util/checkbashisms
+	${PYTHON_DEPS}
+)"
+
+RDEPEND="net-misc/rsync"
+
+MY_PN="${PN/#github-/}"
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+src_compile() {
+	:;
+}
+
+src_install() {
+	dobin bin/*
+	insinto usr/share/${PN}
+	doins share/${PN}/version
+
+	exeinto usr/share/${PN}
+	doexe share/${PN}/bm.sh
+	doexe share/${PN}/ghe-*
+
+	insinto etc/${PN}
+	newins backup.config-example backup.config
+}
+
+src_test() {
+	emake test
+}