app-admin/system-config-printer: 1.5.11 version bump, EAPI-6 bump

Switch to new HOMEPAGE.
Switch to python3.
Switch to gnome-base/libgnome-keyring.
Fix license, drop LINGUAS hack.

Closes: https://bugs.gentoo.org/647088

Thanks-to: poncho <poncho@spahan.ch>
Thanks-to: Drunkard Zhang <gongfan193@gmail.com>
Thanks-to: Mart Raudsepp <leio@gentoo.org>
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

1 files changed, 89 insertions, 0 deletions

diff --git a/app-admin/system-config-printer/system-config-printer-1.5.11.ebuild b/app-admin/system-config-printer/system-config-printer-1.5.11.ebuild
new file mode 100644
index 000000000000..0d78b3182a04
--- /dev/null
+++ b/app-admin/system-config-printer/system-config-printer-1.5.11.ebuild
@@ -0,0 +1,89 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python3_{5,6} )
+PYTHON_REQ_USE="xml"
+inherit gnome2 python-single-r1 systemd
+
+DESCRIPTION="Graphical user interface for CUPS administration"
+HOMEPAGE="https://github.com/zdohnal/system-config-printer"
+SRC_URI="https://github.com/zdohnal/${PN}/releases/download/${PV}/${P}.tar.xz
+	https://dev.gentoo.org/~asturm/distfiles/${P}-patchset-01.tar.xz"
+
+LICENSE="GPL-2+"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~sh ~sparc ~x86"
+SLOT="0"
+
+IUSE="doc gnome-keyring policykit"
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+# Needs cups running, bug 284005
+RESTRICT="test"
+
+# Additional unhandled dependencies
+# gnome-extra/gnome-packagekit[${PYTHON_USEDEP}] with pygobject:2 ?
+# python samba client: smbc
+# selinux: needed for troubleshooting
+RDEPEND="${PYTHON_DEPS}
+	dev-libs/glib:2
+	dev-libs/libxml2[python,${PYTHON_USEDEP}]
+	dev-python/dbus-python[${PYTHON_USEDEP}]
+	dev-python/pycairo[${PYTHON_USEDEP}]
+	>=dev-python/pycups-1.9.60[${PYTHON_USEDEP}]
+	dev-python/pycurl[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	net-print/cups[dbus]
+	virtual/libusb:1
+	>=virtual/udev-172
+	x11-libs/gtk+:3[introspection]
+	x11-libs/libnotify[introspection]
+	x11-libs/pango[introspection]
+	gnome-keyring? ( app-crypt/libsecret[introspection] )
+	policykit? ( >=sys-auth/polkit-0.104-r1 )
+"
+DEPEND="${RDEPEND}
+	app-text/docbook-xml-dtd:4.1.2
+	>=app-text/xmlto-0.0.22
+	dev-util/desktop-file-utils
+	dev-util/intltool
+	sys-devel/gettext
+	virtual/pkgconfig
+	doc? ( dev-python/epydoc )
+"
+
+PATCHES=(
+	"${WORKDIR}"/${P}-auth-dialog.patch
+	"${WORKDIR}"/${P}-libsecret-optional-{1,2}.patch
+	"${WORKDIR}"/${P}-scp-dbus-service-{1,2}.patch
+	"${WORKDIR}"/${P}-typo.patch
+	"${WORKDIR}"/${P}-appdata.patch
+	"${WORKDIR}"/${P}-empty-LC_MESSAGES.patch
+	"${WORKDIR}"/${P}-fdopen-utf8.patch
+	"${WORKDIR}"/${P}-typeerror.patch
+	"${WORKDIR}"/${P}-debugprint-typo.patch
+)
+
+pkg_setup() {
+	python-single-r1_pkg_setup
+}
+
+src_configure() {
+	gnome2_src_configure \
+		--enable-nls \
+		--with-desktop-vendor=Gentoo \
+		--with-udev-rules \
+		--with-systemdsystemunitdir=$(systemd_get_systemunitdir)
+}
+
+src_compile() {
+	gnome2_src_compile
+	use doc && emake html
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( html/. )
+	gnome2_src_install
+	python_fix_shebang "${ED}"
+}