app-arch/brotli: fix pkg-config linker configuration

Closes: https://bugs.gentoo.org/739832
Package-Manager: Portage-3.0.6, Repoman-3.0.1
Signed-off-by: Craig Andrews <candrews@gentoo.org>

1 files changed, 83 insertions, 0 deletions

diff --git a/app-arch/brotli/brotli-1.0.9-r1.ebuild b/app-arch/brotli/brotli-1.0.9-r1.ebuild
new file mode 100644
index 000000000000..41f9c0f5016a
--- /dev/null
+++ b/app-arch/brotli/brotli-1.0.9-r1.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+PYTHON_COMPAT=( python3_{6,7,8,9} )
+DISTUTILS_OPTIONAL="1"
+DISTUTILS_IN_SOURCE_BUILD="1"
+
+inherit cmake-multilib distutils-r1
+
+DESCRIPTION="Generic-purpose lossless compression algorithm"
+HOMEPAGE="https://github.com/google/brotli"
+
+SLOT="0/$(ver_cut 1)"
+
+RDEPEND="python? ( ${PYTHON_DEPS} )"
+DEPEND="${RDEPEND}"
+
+IUSE="python test"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+LICENSE="MIT python? ( Apache-2.0 )"
+
+DOCS=( README.md CONTRIBUTING.md )
+
+if [[ ${PV} == "9999" ]] ; then
+	SRC_URI=""
+	EGIT_REPO_URI="https://github.com/google/${PN}.git"
+	inherit git-r3
+else
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos ~x64-solaris"
+	SRC_URI="https://github.com/google/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+fi
+
+RESTRICT="!test? ( test )"
+
+PATCHES=(
+	"${FILESDIR}/${PV}-linker.patch"
+)
+
+src_prepare() {
+	use python && distutils-r1_src_prepare
+	cmake-utils_src_prepare
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTING="$(usex test)"
+	)
+	cmake-utils_src_configure
+}
+src_configure() {
+	cmake-multilib_src_configure
+	use python && distutils-r1_src_configure
+}
+
+multilib_src_compile() {
+	cmake-utils_src_compile
+}
+src_compile() {
+	cmake-multilib_src_compile
+	use python && distutils-r1_src_compile
+}
+
+python_test() {
+	esetup.py test || die
+}
+
+multilib_src_test() {
+	cmake-utils_src_test
+}
+src_test() {
+	cmake-multilib_src_test
+	use python && distutils-r1_src_test
+}
+
+multilib_src_install() {
+	cmake-utils_src_install
+}
+multilib_src_install_all() {
+	use python && distutils-r1_src_install
+}