app-arch/zoo: new EAPI=6 revision to fix two bugs.

This new revision updates to EAPI=6 and switches our upstream to
Debian. Doing so obsoletes most of our custom patches, and fixes the
build with -Werror=format-security.

The LICENSE variable has also been updated to "public-domain", since
the author released it as such to Debian in an email. That means the
"zoo" license will soon be unused.

Two things may come back to bite me:

  * I omitted the "gcc fixes" patch, because there is no indication
    of what it's supposed to fix. The thing builds fine here.

  * I switched the "make" command back to "emake", because that's how
    it should be. If it still causes problems with BSD systems, I
    guess we can put it back.

The program is still announcing that it's copyrighted, but that will
have to be patched out.

Gentoo-Bug: 520476
Gentoo-Bug: 614674

Package-Manager: Portage-2.3.3, Repoman-2.3.1

1 files changed, 34 insertions, 0 deletions

diff --git a/app-arch/zoo/zoo-2.10-r5.ebuild b/app-arch/zoo/zoo-2.10-r5.ebuild
new file mode 100644
index 000000000000..68ba0e6602c7
--- /dev/null
+++ b/app-arch/zoo/zoo-2.10-r5.ebuild
@@ -0,0 +1,34 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit toolchain-funcs
+
+DESCRIPTION="Manipulate archives of files in compressed form"
+HOMEPAGE="https://packages.debian.org/sid/utils/zoo"
+SRC_URI="http://http.debian.net/debian/pool/main/z/${PN}/${PN}_${PV}.orig.tar.gz
+	http://http.debian.net/debian/pool/main/z/${PN}/${PN}_${PV}-28.debian.tar.xz"
+
+LICENSE="public-domain"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux ~m68k-mint ~sparc-solaris ~x86-solaris"
+IUSE=""
+
+S="${WORKDIR}/${P}.orig"
+
+PATCHES=( "${FILESDIR}/zoo-2.10-gentoo-fbsd-r1.patch" )
+
+src_prepare() {
+	eapply "${WORKDIR}"/debian/patches/*.patch
+	default
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)" linux
+}
+
+src_install() {
+	dobin zoo fiz
+	doman zoo.1 fiz.1
+}