app-backup/rdup: new package.

(Imported from rdup-1.1.14 import from Sunrise, EAPI & version bumped).

Package-Manager: portage-2.3.2
Fixes: https://bugs.gentoo.org/show_bug.cgi?id=196309
Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>

1 files changed, 42 insertions, 0 deletions

diff --git a/app-backup/rdup/rdup-1.1.15.ebuild b/app-backup/rdup/rdup-1.1.15.ebuild
new file mode 100644
index 000000000000..952ae221709b
--- /dev/null
+++ b/app-backup/rdup/rdup-1.1.15.ebuild
@@ -0,0 +1,42 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Header: $
+
+EAPI=6
+
+inherit eutils autotools
+
+DESCRIPTION="Generate a file list suitable for full or incremental backups"
+HOMEPAGE="https://github.com/miekg/rdup/releases"
+SRC_URI="https://github.com/miekg/rdup/archive/${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="debug test"
+
+RDEPEND="
+	app-arch/libarchive
+	dev-libs/glib:2
+	dev-libs/libpcre
+	dev-libs/nettle"
+DEPEND="${RDEPEND}
+	test? ( dev-util/dejagnu )"
+
+src_prepare() {
+	default_src_prepare
+	sed -i -e 's/ -Werror//' GNUmakefile.in || die "Failed to fix Makefile"
+	eautoreconf
+}
+
+src_configure() {
+	econf $(use_enable debug)
+}
+
+src_test() {
+	if use debug; then
+		ewarn "Test phase skipped, as it is known to fail with USE=\"debug\"."
+	else
+		default_src_test
+	fi
+}