app-benchmarks/stress-ng: bump to version 0.12.08

Package-Manager: Portage-3.0.18, Repoman-3.0.3
Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

1 files changed, 48 insertions, 0 deletions

diff --git a/app-benchmarks/stress-ng/stress-ng-0.12.08.ebuild b/app-benchmarks/stress-ng/stress-ng-0.12.08.ebuild
new file mode 100644
index 000000000000..a29434661e67
--- /dev/null
+++ b/app-benchmarks/stress-ng/stress-ng-0.12.08.ebuild
@@ -0,0 +1,48 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit optfeature toolchain-funcs
+
+DESCRIPTION="Stress test for a computer system with various selectable ways"
+HOMEPAGE="https://kernel.ubuntu.com/~cking/stress-ng/"
+SRC_URI="https://kernel.ubuntu.com/~cking/tarballs/${PN}/${P}.tar.xz"
+
+LICENSE="GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
+
+DEPEND="
+	dev-libs/libaio
+	dev-libs/libbsd
+	dev-libs/libgcrypt:0=
+	sys-apps/attr
+	sys-apps/keyutils:=
+	sys-libs/libcap
+	sys-libs/zlib
+"
+
+RDEPEND="${DEPEND}"
+
+DOCS=( "README" "README.Android" "TODO" "syscalls.txt" )
+
+src_prepare() {
+	default
+
+	# Don't reset build jobs to '-j0'
+	sed -e '/-f Makefile.config/s/-j//' -i Makefile || die
+}
+
+src_compile() {
+	export MAN_COMPRESS=0
+	export VERBOSE=1
+	tc-export CC
+
+	default
+}
+
+pkg_postinst() {
+	optfeature "AppArmor support" sys-libs/libapparmor
+	optfeature "SCTP support" net-misc/lksctp-tools
+}