proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 83 insertions, 0 deletions

diff --git a/app-crypt/gcr/gcr-3.14.0.ebuild b/app-crypt/gcr/gcr-3.14.0.ebuild
new file mode 100644
index 000000000000..917387172780
--- /dev/null
+++ b/app-crypt/gcr/gcr-3.14.0.ebuild
@@ -0,0 +1,83 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+GCONF_DEBUG="no"
+VALA_USE_DEPEND="vapigen"
+PYTHON_COMPAT=( python2_7 )
+
+inherit autotools eutils gnome2 python-any-r1 vala virtualx
+
+DESCRIPTION="Libraries for cryptographic UIs and accessing PKCS#11 modules"
+HOMEPAGE="https://developer.gnome.org/gcr/"
+
+LICENSE="GPL-2+ LGPL-2+"
+SLOT="0/1" # subslot = suffix of libgcr-3
+IUSE="debug gtk +introspection vala"
+REQUIRED_USE="vala? ( introspection )"
+KEYWORDS="alpha amd64 arm ~arm64 ia64 ~mips ppc ppc64 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~arm-linux ~x86-linux ~sparc-solaris ~x86-solaris"
+
+COMMON_DEPEND="
+	>=app-crypt/gnupg-2
+	>=app-crypt/p11-kit-0.19
+	>=dev-libs/glib-2.38:2
+	>=dev-libs/libgcrypt-1.2.2:0=
+	>=dev-libs/libtasn1-1:=
+	>=sys-apps/dbus-1
+	gtk? ( >=x11-libs/gtk+-3.12:3[X,introspection?] )
+	introspection? ( >=dev-libs/gobject-introspection-1.34 )
+"
+RDEPEND="${COMMON_DEPEND}
+	!<gnome-base/gnome-keyring-3.3
+"
+# gcr was part of gnome-keyring until 3.3
+DEPEND="${COMMON_DEPEND}
+	${PYTHON_DEPS}
+	dev-libs/gobject-introspection-common
+	dev-libs/libxslt
+	dev-libs/vala-common
+	dev-util/gdbus-codegen
+	>=dev-util/gtk-doc-am-1.9
+	>=dev-util/intltool-0.35
+	sys-devel/gettext
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+# eautoreconf needs:
+#	dev-libs/gobject-introspection-common
+#	dev-libs/vala-common
+
+pkg_setup() {
+	python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	# Fix race building gdbus-codegen header and source (from '3.14')
+	epatch "${FILESDIR}"/${P}-race-building.patch
+
+	# Disable stupid flag changes
+	sed -e 's/CFLAGS="$CFLAGS -g"//' \
+		-e 's/CFLAGS="$CFLAGS -O0"//' \
+		-i configure.ac configure || die
+
+	eautoreconf
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	DOCS="AUTHORS ChangeLog HACKING NEWS README"
+	gnome2_src_configure \
+		$(use_with gtk) \
+		$(use_enable introspection) \
+		$(use_enable vala) \
+		$(usex debug --enable-debug=yes --enable-debug=default) \
+		--disable-update-icon-cache \
+		--disable-update-mime
+}
+
+src_test() {
+	unset DBUS_SESSION_BUS_ADDRESS
+	Xemake check
+}