app-crypt/tpm2-tss: Bump to version 2.4.1

Package-Manager: Portage-2.3.99, Repoman-2.3.22
Signed-off-by: Salah Coronya <salah.coronya@gmail.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 78 insertions, 0 deletions

diff --git a/app-crypt/tpm2-tss/tpm2-tss-2.4.1.ebuild b/app-crypt/tpm2-tss/tpm2-tss-2.4.1.ebuild
new file mode 100644
index 000000000000..88361331ec27
--- /dev/null
+++ b/app-crypt/tpm2-tss/tpm2-tss-2.4.1.ebuild
@@ -0,0 +1,78 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools linux-info tmpfiles udev
+
+DESCRIPTION="TCG Trusted Platform Module 2.0 Software Stack"
+HOMEPAGE="https://github.com/tpm2-software/tpm2-tss"
+SRC_URI="https://github.com/tpm2-software/${PN}/releases/download/${PV}/${P}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="doc +fapi gcrypt +openssl static-libs test"
+
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="^^ ( gcrypt openssl )
+		fapi? ( openssl !gcrypt )"
+
+RDEPEND="acct-group/tss
+	acct-user/tss
+	fapi? (
+		dev-libs/json-c
+		net-misc/curl
+	)
+	gcrypt? ( dev-libs/libgcrypt:0= )
+	openssl? ( dev-libs/openssl:0= )"
+DEPEND="${RDEPEND}
+	test? ( dev-util/cmocka )"
+BDEPEND="virtual/pkgconfig
+	doc? ( app-doc/doxygen )"
+
+PATCHES=(
+	"${FILESDIR}/${P}-Dont-run-systemd-sysusers-in-Makefile.patch"
+	"${FILESDIR}/${P}-configure.ac-wrap-PKG_CHECK_MODULES-in-braces.patch"
+	)
+
+pkg_setup() {
+	local CONFIG_CHECK=" \
+		~TCG_TPM
+	"
+	linux-info_pkg_setup
+	kernel_is ge 4 12 0 || ewarn "At least kernel 4.12.0 is required"
+}
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		--localstatedir=/var \
+		$(use_enable doc doxygen-doc) \
+		$(use_enable fapi) \
+		$(use_enable static-libs static) \
+		$(use_enable test unit) \
+		--disable-tcti-mssim \
+		--disable-defaultflags \
+		--disable-weakcrypto \
+		--with-crypto="$(usex gcrypt gcrypt ossl)" \
+		--with-runstatedir=/run \
+		--with-udevrulesdir="$(get_udevdir)/rules.d" \
+		--with-udevrulesprefix=60- \
+		--with-sysusersdir="/usr/lib/sysusers.d" \
+		--with-tmpfilesdir="/usr/lib/tmpfiles.d"
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+}
+
+pkg_postinst() {
+	tmpfiles_process tpm2-tss-fapi.conf
+}