app-emulation/fuse-utils: sync USE=audiofile with libspectrum, bump to EAPI-7

Signed-off-by: Marek Szuba <marecki@gentoo.org>

1 files changed, 43 insertions, 0 deletions

diff --git a/app-emulation/fuse-utils/fuse-utils-1.4.3-r1.ebuild b/app-emulation/fuse-utils/fuse-utils-1.4.3-r1.ebuild
new file mode 100644
index 000000000000..cc6f021a658a
--- /dev/null
+++ b/app-emulation/fuse-utils/fuse-utils-1.4.3-r1.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit autotools
+
+DESCRIPTION="Utils for the Free Unix Spectrum Emulator by Philip Kendall"
+HOMEPAGE="http://fuse-emulator.sourceforge.net"
+SRC_URI="mirror://sourceforge/fuse-emulator/${P}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="audiofile gcrypt jpeg png zlib"
+
+RDEPEND=">=app-emulation/libspectrum-1.4.4[audiofile?,gcrypt?,zlib?]
+	audiofile? ( >=media-libs/audiofile-0.3.6 )
+	jpeg? ( virtual/jpeg:0 )
+	png? ( media-libs/libpng:0 )
+	zlib? ( sys-libs/zlib )"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}"/remove-local-prefix.patch
+)
+
+src_prepare() {
+	default
+	eautoreconf
+}
+
+src_configure() {
+	local myconf=(
+		$(use_with audiofile)
+		$(use_with gcrypt libgcrypt)
+		$(use_with jpeg libjpeg)
+		$(use_with png libpng)
+		$(use_with zlib)
+	)
+	econf "${myconf[@]}"
+}