proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 93 insertions, 0 deletions

diff --git a/app-emulation/virt-manager/virt-manager-1.2.1.ebuild b/app-emulation/virt-manager/virt-manager-1.2.1.ebuild
new file mode 100644
index 000000000000..b79811547c1d
--- /dev/null
+++ b/app-emulation/virt-manager/virt-manager-1.2.1.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+PYTHON_COMPAT=( python2_7 )
+DISTUTILS_SINGLE_IMPL=1
+
+inherit gnome2 distutils-r1
+
+DESCRIPTION="A graphical tool for administering virtual machines"
+HOMEPAGE="http://virt-manager.org"
+
+if [[ ${PV} = *9999* ]]; then
+	inherit git-2
+	SRC_URI=""
+	KEYWORDS=""
+	EGIT_REPO_URI="git://git.fedorahosted.org/virt-manager.git"
+else
+	SRC_URI="http://virt-manager.org/download/sources/${PN}/${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="gnome-keyring gtk policykit sasl"
+
+RDEPEND="!app-emulation/virtinst
+	dev-python/libvirt-python[${PYTHON_USEDEP}]
+	>=app-emulation/libvirt-glib-0.0.9[introspection,python,${PYTHON_USEDEP}]
+	${PYTHON_DEPS}
+	dev-libs/libxml2[python,${PYTHON_USEDEP}]
+	dev-python/ipaddr[${PYTHON_USEDEP}]
+	dev-python/pygobject:3[${PYTHON_USEDEP}]
+	dev-python/urlgrabber[${PYTHON_USEDEP}]
+	sys-libs/libosinfo[introspection]
+	gtk? (
+		x11-libs/gtk+:3[introspection]
+		gnome-base/dconf
+		>=net-libs/gtk-vnc-0.3.8[gtk3,introspection,python,${PYTHON_USEDEP}]
+		net-misc/spice-gtk[usbredir,gtk3,introspection,python,sasl?,${PYTHON_USEDEP}]
+		net-misc/x11-ssh-askpass
+		x11-libs/vte:2.90[introspection]
+		gnome-keyring? ( dev-python/gnome-keyring-python )
+		policykit? ( sys-auth/polkit[introspection] )
+		x11-themes/gnome-icon-theme
+	)"
+DEPEND="${RDEPEND}
+	dev-lang/perl
+	dev-util/intltool"
+
+DOCS=( README NEWS )
+
+src_prepare() {
+	distutils-r1_src_prepare
+}
+
+distutils-r1_python_compile() {
+	local defgraphics=
+
+	esetup.py configure \
+		--qemu-user=qemu \
+		--default-graphics=spice
+}
+
+python_install_all() {
+	distutils-r1_python_install_all
+	python_fix_shebang \
+		"${ED}"/usr/share/virt-manager/virt-{clone,convert,install,manager}
+}
+
+pkg_preinst() {
+	if use gtk; then
+		gnome2_pkg_preinst
+
+		cd "${ED}"
+		export GNOME2_ECLASS_ICONS=$(find 'usr/share/virt-manager/icons' -maxdepth 1 -mindepth 1 -type d 2> /dev/null)
+	else
+		rm -rf "${ED}/usr/share/virt-manager/virtManager"
+		rm -f "${ED}/usr/share/virt-manager/virt-manager"
+		rm -rf "${ED}/usr/share/virt-manager/ui/"
+		rm -rf "${ED}/usr/share/virt-manager/icons/"
+		rm -rf "${ED}/usr/share/man/man1/virt-manager.1*"
+		rm -rf "${ED}/usr/share/icons/"
+		rm -rf "${ED}/usr/share/applications/virt-manager.desktop"
+		rm -rf "${ED}/usr/bin/virt-manager"
+	fi
+}
+
+pkg_postinst() {
+	use gtk && gnome2_pkg_postinst
+}