app-metrics/pushgateway: Version bump to 0.6.0

Signed-off-by: Manuel Rüger <mrueg@gentoo.org>
Package-Manager: Portage-2.3.51, Repoman-2.3.11

1 files changed, 51 insertions, 0 deletions

diff --git a/app-metrics/pushgateway/pushgateway-0.6.0.ebuild b/app-metrics/pushgateway/pushgateway-0.6.0.ebuild
new file mode 100644
index 000000000000..846402c8f22a
--- /dev/null
+++ b/app-metrics/pushgateway/pushgateway-0.6.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit user golang-build golang-vcs-snapshot systemd
+
+EGO_PN="github.com/prometheus/pushgateway"
+EGIT_COMMIT="v${PV/_rc/-rc.}"
+GIT_COMMIT="290ff86"
+ARCHIVE_URI="https://${EGO_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+KEYWORDS="~amd64"
+
+DESCRIPTION="Prometheus push acceptor for ephemeral and batch jobs"
+HOMEPAGE="https://github.com/prometheus/pushgateway"
+SRC_URI="${ARCHIVE_URI}"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE=""
+
+DEPEND="dev-util/promu"
+
+pkg_setup() {
+	enewgroup ${PN}
+	enewuser ${PN} -1 -1 -1 ${PN}
+}
+
+src_prepare() {
+	default
+	sed -i -e "s/{{.Revision}}/${GIT_COMMIT}/" src/${EGO_PN}/.promu.yml || die
+}
+
+src_compile() {
+	pushd src/${EGO_PN} || die
+	mkdir -p bin || die
+	GOPATH="${S}" promu build -v --prefix bin || die
+	popd || die
+}
+
+src_install() {
+	pushd src/${EGO_PN} || die
+	dobin bin/pushgateway
+	dodoc {README,CHANGELOG,CONTRIBUTING}.md
+	popd || die
+	keepdir /var/lib/${PN} /var/log/${PN}
+	fowners ${PN}:${PN} /var/lib/${PN} /var/log/${PN}
+	newinitd "${FILESDIR}"/${PN}-1.initd ${PN}
+	newconfd "${FILESDIR}"/${PN}-1.confd ${PN}
+	insinto /etc/logrotate.d
+	newins "${FILESDIR}/${PN}.logrotated" "${PN}"
+	systemd_dounit "${FILESDIR}/${PN}-1.service"
+}