app-portage/emerge-delta-webrsync: version bump to 3.7.5

Package-Manager: Portage-2.3.43, Repoman-2.3.10

1 files changed, 46 insertions, 0 deletions

diff --git a/app-portage/emerge-delta-webrsync/emerge-delta-webrsync-3.7.5.ebuild b/app-portage/emerge-delta-webrsync/emerge-delta-webrsync-3.7.5.ebuild
new file mode 100644
index 000000000000..aa4a0ca9e919
--- /dev/null
+++ b/app-portage/emerge-delta-webrsync/emerge-delta-webrsync-3.7.5.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=5
+DESCRIPTION="emerge-webrsync using patches to minimize bandwidth"
+HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Portage"
+SRC_URI="https://gitweb.gentoo.org/proj/portage.git/plain/misc/emerge-delta-webrsync?id=b8c070708bbc6d0db544d4b04b530d6d03d39bb5 -> ${P}"
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~hppa ~ia64 ~mips ~ppc ~sparc ~x86 ~x86-fbsd"
+IUSE=""
+
+DEPEND=""
+RDEPEND="
+	app-shells/bash
+	|| (
+		>=sys-apps/portage-2.1.10
+		sys-apps/portage-mgorny
+	)
+	>=dev-util/diffball-0.6.5"
+
+S=${WORKDIR}
+
+src_unpack() {
+	cp "${DISTDIR}/${P}" "${WORKDIR}/" || die
+}
+
+src_install() {
+	newbin ${P} ${PN}
+	keepdir /var/delta-webrsync
+	fperms 0770 /var/delta-webrsync
+}
+
+pkg_preinst() {
+	# Failure here is non-fatal, since the "portage" group
+	# doesn't necessarily exist on prefix systems.
+	chgrp portage "${ED}"/var/delta-webrsync 2>/dev/null
+}
+
+pkg_postinst() {
+	if [[ -z ${REPLACING_VERSIONS} ]] && \
+		! has_version app-arch/tarsync ; then
+		elog "For maximum emerge-delta-webrsync" \
+			"performance, install app-arch/tarsync."
+	fi
+}