app-text/convertlit: new revision supporting $(AR).

This new revision adds a trivial patch replacing "ar" in one of the
Makefiles with $(AR), which defaults to "ar" anyway.

Gentoo-Bug: 571874

Package-Manager: portage-2.2.28

1 files changed, 45 insertions, 0 deletions

diff --git a/app-text/convertlit/convertlit-1.8-r3.ebuild b/app-text/convertlit/convertlit-1.8-r3.ebuild
new file mode 100644
index 000000000000..e984d0215947
--- /dev/null
+++ b/app-text/convertlit/convertlit-1.8-r3.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2016 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=6
+
+inherit toolchain-funcs
+
+MY_P="clit${PV//./}"
+
+DESCRIPTION="CLit converts MS ebook .lit files to .opf (xml+html+png+jpg)"
+HOMEPAGE="http://www.convertlit.com/"
+SRC_URI="http://www.convertlit.com/${MY_P}src.zip"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~x86 ~amd64-fbsd ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE=""
+
+RDEPEND=">=dev-libs/libtommath-0.36-r1"
+
+DEPEND="${RDEPEND}
+	app-arch/unzip"
+
+S="${WORKDIR}"
+
+PATCHES=(
+	"${FILESDIR}/${P}-respectflags-r1.patch"
+	"${FILESDIR}/fix-Wformat-security-warnings.patch"
+	"${FILESDIR}/support-ar-variable.patch"
+)
+
+src_compile() {
+	tc-export CC
+
+	cd "${S}/lib" || die "failed to change into ${S}/lib directory"
+	emake
+	cd "${S}/${MY_P}" || die "failed to change into ${S}/${MY_P} directory"
+	emake
+}
+
+src_install() {
+	einstalldocs
+	dobin "${MY_P}/clit"
+}