app-text/zathura-pdf-poppler: Version bump.

Package-Manager: Portage-2.3.20, Repoman-2.3.6

1 files changed, 46 insertions, 0 deletions

diff --git a/app-text/zathura-pdf-poppler/zathura-pdf-poppler-0.2.8.ebuild b/app-text/zathura-pdf-poppler/zathura-pdf-poppler-0.2.8.ebuild
new file mode 100644
index 000000000000..ce5b9b60840a
--- /dev/null
+++ b/app-text/zathura-pdf-poppler/zathura-pdf-poppler-0.2.8.ebuild
@@ -0,0 +1,46 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils toolchain-funcs xdg
+
+if [[ ${PV} == *9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://git.pwmt.org/pwmt/zathura-pdf-poppler.git"
+	EGIT_BRANCH="develop"
+else
+	KEYWORDS="~amd64 ~arm ~x86"
+	SRC_URI="http://pwmt.org/projects/zathura/plugins/download/${P}.tar.gz"
+fi
+
+DESCRIPTION="PDF plug-in for zathura"
+HOMEPAGE="http://pwmt.org/projects/zathura/"
+
+LICENSE="ZLIB"
+SLOT="0"
+IUSE=""
+
+RDEPEND="app-text/poppler:=[cairo]
+	>=app-text/zathura-0.3.8
+	x11-libs/cairo:="
+DEPEND="${RDEPEND}
+	virtual/pkgconfig"
+
+src_configure() {
+	myzathuraconf=(
+		CC="$(tc-getCC)"
+		LD="$(tc-getLD)"
+		VERBOSE=1
+		DESTDIR="${D}"
+	)
+}
+
+src_compile() {
+	emake "${myzathuraconf[@]}"
+}
+
+src_install() {
+	emake "${myzathuraconf[@]}" install
+	dodoc AUTHORS
+}