dev-ada/gtkada: bump to 2021

Package-Manager: Portage-3.0.18, Repoman-3.0.2
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

1 files changed, 63 insertions, 0 deletions

diff --git a/dev-ada/gtkada/gtkada-2021.ebuild b/dev-ada/gtkada/gtkada-2021.ebuild
new file mode 100644
index 000000000000..5c7bbffbef1e
--- /dev/null
+++ b/dev-ada/gtkada/gtkada-2021.ebuild
@@ -0,0 +1,63 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ADA_COMPAT=( gnat_201{7..9} gnat_202{0..1} )
+inherit ada autotools multiprocessing
+
+MYP=${P}-${PV}0518-1A011-src
+ADAMIRROR=https://community.download.adacore.com/v1
+ID=8f1daefcb56e3ee7feaad67bac66deb0f7c37a82
+
+DESCRIPTION="A complete Ada graphical toolkit"
+HOMEPAGE="http://libre.adacore.com//tools/gtkada/"
+SRC_URI="${ADAMIRROR}/${ID}?filename=${MYP}.tar.gz -> ${MYP}.tar.gz"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+shared static-libs"
+
+RDEPEND="${ADA_DEPS}
+	dev-libs/atk
+	dev-libs/glib:2
+	media-libs/fontconfig
+	media-libs/freetype
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/pango"
+DEPEND="${RDEPEND}
+	dev-ada/gprbuild[${ADA_USEDEP}]"
+
+REQUIRED_USE="${ADA_REQUIRED_USE}"
+
+S="${WORKDIR}"/${MYP}
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-2017-r1-gentoo.patch
+	"${FILESDIR}"/${PN}-2019-gentoo.patch
+)
+
+src_prepare() {
+	default
+	mv configure.{in,ac} || die
+	eautoreconf
+}
+
+src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		$(use_enable shared) \
+		--without-GL
+}
+
+src_compile() {
+	emake -j1 PROCESSORS=$(makeopts_jobs)
+}
+
+src_install() {
+	emake -j1 DESTDIR="${D}"
+	einstalldocs
+}