dev-ada/libgpr: rename library

Closes: https://bugs.gentoo.org/818505
Package-Manager: Portage-3.0.30, Repoman-3.0.3
Signed-off-by: Alfredo Tupone <tupone@gentoo.org>

2 files changed, 75 insertions, 1 deletions

diff --git a/dev-ada/libgpr/libgpr-2021-r1.ebuild b/dev-ada/libgpr/libgpr-2021-r1.ebuild
new file mode 100644
index 000000000000..6f89e775d4eb
--- /dev/null
+++ b/dev-ada/libgpr/libgpr-2021-r1.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+ADA_COMPAT=( gnat_202{0..1} )
+inherit ada multiprocessing
+
+MYP=gprbuild-${PV}-${PV}0519-19A34-src
+ID=23a77a37247ff811609e23a0a271f445c299fc8f
+ADAMIRROR=https://community.download.adacore.com/v1
+
+DESCRIPTION="Ada library to handle GPRbuild project files"
+HOMEPAGE="http://libre.adacore.com/"
+SRC_URI="${ADAMIRROR}/${ID}?filename=${MYP}.tar.gz -> ${MYP}.tar.gz"
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="+shared static-libs static-pic"
+
+RDEPEND="dev-ada/xmlada[shared?,static-libs?,static-pic?,${ADA_USEDEP}]
+	!net-libs/grpc"
+DEPEND="${RDEPEND}
+	dev-ada/gprbuild[${ADA_USEDEP}]"
+REQUIRED_USE="${ADA_REQUIRED_USE}
+	|| ( shared static-libs static-pic )"
+
+S="${WORKDIR}"/${MYP}
+
+PATCHES=( "${FILESDIR}"/${PN}-2020-gentoo.patch )
+
+src_prepare() {
+	default
+	sed -i -e '/Library_Name/s|gpr|gnatgpr|' gpr/gpr.gpr || die
+}
+
+src_configure() {
+	emake setup
+}
+
+src_compile() {
+	build () {
+		gprbuild -p -m -j$(makeopts_jobs) -XBUILD=production -v \
+			-XLIBRARY_TYPE=$1 -XXMLADA_BUILD=$1 \
+			gpr/gpr.gpr -cargs:C ${CFLAGS} -cargs:Ada ${ADAFLAGS} || die
+	}
+	if use shared; then
+		build relocatable
+	fi
+	if use static-libs; then
+		build static
+	fi
+	if use static-pic; then
+		build static-pic
+	fi
+}
+
+src_install() {
+	if use static-libs; then
+		emake prefix="${D}"/usr libgpr.install.static
+	fi
+	for kind in shared static-pic; do
+		if use ${kind}; then
+			emake prefix="${D}"/usr libgpr.install.${kind}
+		fi
+	done
+	rm -r "${D}"/usr/share/gpr/manifests || die
+	einstalldocs
+}
diff --git a/dev-ada/libgpr/libgpr-22.0.0.ebuild b/dev-ada/libgpr/libgpr-22.0.0-r1.ebuild
index 68bf6f6c798f..f613771b4903 100644
--- a/dev-ada/libgpr/libgpr-22.0.0.ebuild
+++ b/dev-ada/libgpr/libgpr-22.0.0-r1.ebuild
@@ -1,4 +1,4 @@
-# Copyright 1999-2021 Gentoo Authors
+# Copyright 1999-2022 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
 EAPI=7
@@ -29,6 +29,11 @@ S="${WORKDIR}"/${MYP}
 
 PATCHES=( "${FILESDIR}"/${PN}-2020-gentoo.patch )
 
+src_prepare() {
+	default
+	sed -i -e '/Library_Name/s|gpr|gnatgpr|' gpr/gpr.gpr || die
+}
+
 src_configure() {
 	emake setup
 }