dev-cpp/asio: version 1.20.0

Package-Manager: Portage-3.0.20, Repoman-3.0.3
Signed-off-by: Alexey Sokolov <alexey+gentoo@asokolov.org>
Closes: https://github.com/gentoo/gentoo/pull/22601
Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

1 files changed, 49 insertions, 0 deletions

diff --git a/dev-cpp/asio/asio-1.20.0.ebuild b/dev-cpp/asio/asio-1.20.0.ebuild
new file mode 100644
index 000000000000..0b91e779c0be
--- /dev/null
+++ b/dev-cpp/asio/asio-1.20.0.ebuild
@@ -0,0 +1,49 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DESCRIPTION="Asynchronous Network Library"
+HOMEPAGE="https://think-async.com https://github.com/chriskohlhoff/asio"
+SRC_URI="mirror://sourceforge/${PN}/${PN}/${P}.tar.bz2"
+
+LICENSE="Boost-1.0"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+IUSE="doc examples test"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	test? (
+		dev-libs/boost
+		dev-libs/openssl
+	)
+"
+
+src_prepare() {
+	default
+
+	if ! use test; then
+		# Don't build nor install any examples or unittests
+		# since we don't have a script to run them
+		cat > src/Makefile.in <<-EOF || die
+			all:
+
+			install:
+
+			clean:
+		EOF
+	fi
+}
+
+src_install() {
+	use doc && local HTML_DOCS=( doc/. )
+	default
+
+	if use examples; then
+		# Get rid of the object files
+		emake clean
+		dodoc -r src/examples
+		docompress -x /usr/share/doc/${PF}/examples
+	fi
+}