dev-db/freetds: new version 1.00.341 from the "current" series.

This apparently-huge version jump, from 1.00.54 to 1.00.341, comes as
we switch from the upstream "stable" release series to the "current"
one. The stable series is just, well, too stable for us: there have
been a number of bug fixes (Gentoo bug 621430, for example) that never
made it into a stable release.

The "current" series should follow the upstream git repository more
closely; they're snapshots of one manner or another. It looks to me
like (and I have my fingers crossed that) the version numbers for the
stable and current series to not overlap.

Closes: https://bugs.gentoo.org/621430
Package-Manager: Portage-2.3.19, Repoman-2.3.6

1 files changed, 62 insertions, 0 deletions

diff --git a/dev-db/freetds/freetds-1.00.341.ebuild b/dev-db/freetds/freetds-1.00.341.ebuild
new file mode 100644
index 000000000000..f975c08fe565
--- /dev/null
+++ b/dev-db/freetds/freetds-1.00.341.ebuild
@@ -0,0 +1,62 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+# This is from the "current" release series, because the "stable" series
+# is a little too stable for us (missing bug fixes, and so on).
+MY_PN="${PN}-dev"
+
+DESCRIPTION="Tabular Datastream Library"
+HOMEPAGE="http://www.freetds.org/"
+SRC_URI="ftp://ftp.freetds.org/pub/${PN}/current/${MY_PN}.${PV}.tar.gz"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64
+		  ~s390 ~sh ~sparc ~x86 ~amd64-fbsd ~x86-fbsd ~ppc-macos"
+IUSE="gnutls iconv kerberos libressl mssql iodbc odbc ssl"
+RESTRICT="test"
+
+# sed, grep, and awk are used by the build system and the osql script.
+COMMON_DEPEND="sys-apps/sed
+	sys-apps/grep
+	virtual/awk
+	gnutls? ( net-libs/gnutls )
+	iconv? ( virtual/libiconv )
+	iodbc? ( dev-db/libiodbc )
+	kerberos? ( virtual/krb5 )
+	odbc? ( dev-db/unixODBC )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)"
+
+DEPEND="${COMMON_DEPEND}"
+
+# bind-tools is needed because the osql script calls "host".
+# binutils is for "strings".
+RDEPEND="${COMMON_DEPEND}
+	sys-devel/binutils
+	net-dns/bind-tools"
+
+# iODBC and unixODBC are mutually-exclusive choices for
+# the ODBC driver manager. Future versions of FreeTDS
+# will throw an error if you specify both.
+REQUIRED_USE="?? ( iodbc odbc )"
+
+S="${WORKDIR}/${MY_PN}.${PV}"
+
+src_configure() {
+	local myconf=( $(use_with iodbc) )
+	myconf+=( $(use_with odbc unixodbc "${EPREFIX}/usr") )
+	myconf+=( $(use_enable iconv libiconv) )
+	myconf+=( $(use_with iconv libiconv-prefix "${EPREFIX}/usr") )
+	myconf+=( $(use_enable kerberos krb5) )
+	myconf+=( $(use_enable mssql msdblib) )
+	myconf+=( $(use_with gnutls) )
+	myconf+=( $(use_with ssl openssl "${EPREFIX}/usr") )
+	myconf+=( --docdir="/usr/share/doc/${PF}" )
+
+	econf "${myconf[@]}"
+}