dev-db/sqlitebrowser: Version bump (thanks Fabio Rossi, bug 571048).

Package-Manager: portage-2.2.26

1 files changed, 60 insertions, 0 deletions

diff --git a/dev-db/sqlitebrowser/sqlitebrowser-3.8.0.ebuild b/dev-db/sqlitebrowser/sqlitebrowser-3.8.0.ebuild
new file mode 100644
index 000000000000..c78fb79ee004
--- /dev/null
+++ b/dev-db/sqlitebrowser/sqlitebrowser-3.8.0.ebuild
@@ -0,0 +1,60 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+CMAKE_MAKEFILE_GENERATOR=ninja
+
+inherit eutils cmake-utils
+
+DESCRIPTION="SQLite Database Browser"
+HOMEPAGE="http://sqlitebrowser.org"
+SRC_URI="https://github.com/${PN}/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="GPL-3 MPL-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="qt4 qt5 test"
+
+REQUIRED_USE="^^ ( qt4 qt5 )"
+
+RDEPEND="
+	dev-cpp/antlr-cpp:2=
+	dev-db/sqlite:3
+	dev-libs/qcustomplot[qt5=]
+	x11-libs/qscintilla
+	qt4? (
+		dev-qt/qtcore:4
+		dev-qt/qtgui:4
+	)
+	qt5? (
+		dev-qt/qtnetwork:5
+		dev-qt/qttest:5
+		dev-qt/qtwidgets:5
+	)"
+DEPEND="${RDEPEND}
+	qt5? ( dev-qt/linguist-tools:5 )
+"
+
+PATCHES=( "${FILESDIR}"/${PN}-3.7.0-unbundle.patch )
+
+src_prepare() {
+	# https://github.com/qingfengxia/qhexedit still bundled
+	# x11-libs/qscintilla[qt4?,qt5?] still bundled
+	find libs/{antlr-2.7.7,qcustomplot-source} -delete || die
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		$(cmake-utils_use_use qt5)
+		$(cmake-utils_use_enable test TESTING)
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	doicon images/sqlitebrowser.svg
+}