dev-embedded/libftdi: Version 1.4.

Package-Manager: Portage-2.3.43, Repoman-2.3.10

1 files changed, 73 insertions, 0 deletions

diff --git a/dev-embedded/libftdi/libftdi-1.4.ebuild b/dev-embedded/libftdi/libftdi-1.4.ebuild
new file mode 100644
index 000000000000..08ab82ddbc6c
--- /dev/null
+++ b/dev-embedded/libftdi/libftdi-1.4.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_4 python3_5 python3_6 )
+inherit cmake-utils python-single-r1
+
+MY_P="${PN}1-${PV}"
+if [[ ${PV} == 9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="git://developer.intra2net.com/${PN}"
+else
+	SRC_URI="http://www.intra2net.com/en/developer/${PN}/download/${MY_P}.tar.bz2"
+	KEYWORDS="~amd64 ~arm ~arm64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+fi
+
+DESCRIPTION="Userspace access to FTDI USB interface chips"
+HOMEPAGE="http://www.intra2net.com/en/developer/libftdi/"
+
+LICENSE="LGPL-2"
+SLOT="1"
+IUSE="cxx doc examples python static-libs test tools"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+RDEPEND="virtual/libusb:1
+	cxx? ( dev-libs/boost )
+	python? ( ${PYTHON_DEPS} )
+	tools? (
+		!<dev-embedded/ftdi_eeprom-1.0
+		dev-libs/confuse:=
+	)"
+DEPEND="${RDEPEND}
+	python? ( dev-lang/swig )
+	doc? ( app-doc/doxygen )"
+
+pkg_setup() {
+	use python && python-single-r1_pkg_setup
+}
+
+S=${WORKDIR}/${MY_P}
+
+src_configure() {
+	local mycmakeargs=(
+		-DFTDIPP=$(usex cxx)
+		-DDOCUMENTATION=$(usex doc)
+		-DEXAMPLES=$(usex examples)
+		-DPYTHON_BINDINGS=$(usex python)
+		-DSTATICLIBS=$(usex static-libs)
+		-DBUILD_TESTS=$(usex test)
+		-DFTDI_EEPROM=$(usex tools)
+		-DCMAKE_SKIP_BUILD_RPATH=ON
+	)
+	cmake-utils_src_configure
+}
+
+src_install() {
+	cmake-utils_src_install
+	use python && python_optimize
+	dodoc AUTHORS ChangeLog README TODO
+
+	if use doc ; then
+		# Clean up crap man pages. #356369
+		rm -vf "${CMAKE_BUILD_DIR}"/doc/man/man3/_* || die
+
+		doman "${CMAKE_BUILD_DIR}"/doc/man/man3/*
+		dodoc -r "${CMAKE_BUILD_DIR}"/doc/html
+	fi
+	if use examples ; then
+		docinto examples
+		dodoc examples/*.c
+	fi
+}