dev-go/go-net: 0_pre20150804 version bump

Package-Manager: portage-2.2.20

1 files changed, 43 insertions, 0 deletions

diff --git a/dev-go/go-net/go-net-0_pre20150804.ebuild b/dev-go/go-net/go-net-0_pre20150804.ebuild
new file mode 100644
index 000000000000..953c5bf7cebe
--- /dev/null
+++ b/dev-go/go-net/go-net-0_pre20150804.ebuild
@@ -0,0 +1,43 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+EGO_PN=golang.org/x/net/...
+EGO_SRC=golang.org/x/net
+
+if [[ ${PV} = *9999* ]]; then
+	inherit golang-vcs
+else
+	KEYWORDS="~amd64"
+	EGIT_COMMIT="1bc0720082d79ce7ffc6ef6e523d00d46b0dee45"
+	SRC_URI="https://github.com/golang/net/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	inherit golang-vcs-snapshot
+fi
+inherit golang-build
+
+DESCRIPTION="Go supplementary network libraries"
+HOMEPAGE="https://godoc.org/golang.org/x/net"
+LICENSE="BSD"
+SLOT="0/${PV}"
+IUSE=""
+DEPEND="dev-go/go-text:="
+RDEPEND=""
+
+src_prepare() {
+	# disable broken tests
+	sed -e 's:TestReadProppatch(:_\0:' \
+		-i src/${EGO_SRC}/webdav/xml_test.go || die
+	sed -e 's:TestPingGoogle(:_\0:' \
+		-e 's:TestNonPrivilegedPing(:_\0:' \
+		-i src/${EGO_SRC}/icmp/ping_test.go || die
+}
+
+src_compile() {
+	# Create a writable GOROOT in order to avoid sandbox violations.
+	cp -sR "$(go env GOROOT)" "${T}/goroot" || die
+	rm -rf "${T}/goroot/src/${EGO_SRC}" || die
+	rm -rf "${T}/goroot/pkg/$(go env GOOS)_$(go env GOARCH)/${EGO_SRC}" || die
+	export GOROOT="${T}/goroot"
+	golang-build_src_compile
+}