proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 66 insertions, 0 deletions

diff --git a/dev-java/snappy/snappy-1.1.0.1.ebuild b/dev-java/snappy/snappy-1.1.0.1.ebuild
new file mode 100644
index 000000000000..21c5a5f6be03
--- /dev/null
+++ b/dev-java/snappy/snappy-1.1.0.1.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2013 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI="5"
+
+JAVA_PKG_IUSE="doc source test"
+
+inherit java-pkg-2 java-ant-2
+
+MY_PN="${PN}-java"
+MY_P="${MY_PN}-${PV}"
+
+DESCRIPTION="Snappy compressor/decompressor for Java"
+HOMEPAGE="https://github.com/xerial/snappy-java/"
+SRC_URI="https://github.com/xerial/${MY_PN}/archive/${PV}.tar.gz -> ${PN}-java-${PV}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="1.1"
+KEYWORDS="~amd64 ~x86"
+IUSE=""
+
+CDEPEND="dev-java/osgi-core-api:0
+	app-arch/snappy"
+
+DEPEND=">=virtual/jdk-1.6
+	test? (
+		dev-java/junit:4
+		dev-java/xerial-core:0
+		dev-java/plexus-classworlds:0
+	)
+	${CDEPEND}"
+
+RDEPEND=">=virtual/jre-1.6
+	${CDEPEND}"
+
+S="${WORKDIR}/${MY_P}"
+
+JAVA_ANT_REWRITE_CLASSPATH="true"
+EANT_GENTOO_CLASSPATH="osgi-core-api"
+EANT_TEST_GENTOO_CLASSPATH="${EANT_GENTOO_CLASSPATH},junit-4,xerial-core,plexus-classworlds"
+EANT_TEST_ANT_TASKS="ant-junit"
+
+java_prepare() {
+	cp "${FILESDIR}"/1.x-build.xml "${S}"/build.xml || die
+	rm -r "${S}"/src/main/resources/org/xerial/snappy/native/ || die
+	epatch "${FILESDIR}"/${PV}-unbundle-snappy.patch
+	epatch "${FILESDIR}"/${PV}-gentoo.patch
+}
+
+src_compile() {
+	emake
+	java-pkg-2_src_compile
+}
+
+src_install() {
+	java-pkg_doso "${S}"/target/libsnappyjava.so
+	java-pkg_dojar "${S}/target/${PN}.jar"
+
+	use source && java-pkg_dosrc "${S}"/src/main/java/*
+	use doc && java-pkg_dojavadoc "${S}"/target/site/apidocs
+}
+
+src_test() {
+	java-pkg-2_src_test
+}