dev-lang/duktape: bump to 2.6.0

Bug: https://bugs.gentoo.org/730188
Closes: https://bugs.gentoo.org/752111
Closes: https://bugs.gentoo.org/722192
Package-Manager: Portage-3.0.8, Repoman-3.0.2
Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 51 insertions, 0 deletions

diff --git a/dev-lang/duktape/duktape-2.6.0.ebuild b/dev-lang/duktape/duktape-2.6.0.ebuild
new file mode 100644
index 000000000000..f84cdd45b4bd
--- /dev/null
+++ b/dev-lang/duktape/duktape-2.6.0.ebuild
@@ -0,0 +1,51 @@
+# Copyright 1999-2020 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit toolchain-funcs
+
+DESCRIPTION="Embeddable Javascript engine"
+HOMEPAGE="https://duktape.org"
+SRC_URI="https://duktape.org/${P}.tar.xz"
+
+LICENSE="MIT"
+# Upstream don't maintain binary compatibility
+# https://github.com/svaarala/duktape/issues/1524
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~x86"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-2.6.0-respect-tc-env.patch"
+)
+
+src_prepare() {
+	# Set install path
+	sed -i "s#INSTALL_PREFIX = /usr/local#INSTALL_PREFIX = ${D%/}/usr#" \
+			Makefile.sharedlibrary || die "failed to set install path"
+
+	# Edit pkgconfig
+	sed "s#VERSION#${PV}#" "${FILESDIR}/${PN}.pc" > "${S}/${PN}.pc" || die
+	sed -i "s#LIBDIR#$(get_libdir)#" "${S}/${PN}.pc" || die
+
+	# Set lib folder
+	sed -i "s#(INSTALL_PREFIX)/lib#(INSTALL_PREFIX)/$(get_libdir)#" \
+		Makefile.sharedlibrary || die
+
+	mv Makefile.sharedlibrary Makefile || die "failed to rename makefile"
+
+	default
+}
+
+src_compile() {
+	emake CC="$(tc-getCC)"
+}
+
+src_install() {
+	dodir /usr/$(get_libdir)
+	dodir /usr/include
+	emake install
+
+	insinto /usr/$(get_libdir)/pkgconfig/
+	doins "${S}/${PN}.pc"
+}