proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 94 insertions, 0 deletions

diff --git a/dev-lang/qu-prolog/qu-prolog-9.5.ebuild b/dev-lang/qu-prolog/qu-prolog-9.5.ebuild
new file mode 100644
index 000000000000..9434322dd8a4
--- /dev/null
+++ b/dev-lang/qu-prolog/qu-prolog-9.5.ebuild
@@ -0,0 +1,94 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+
+inherit eutils multilib qmake-utils
+
+MY_P=qp${PV}
+
+DESCRIPTION="Extended Prolog supporting quantifiers, object-variables and substitutions"
+HOMEPAGE="http://www.itee.uq.edu.au/~pjr/HomePages/QuPrologHome.html"
+SRC_URI="http://www.itee.uq.edu.au/~pjr/HomePages/QPFiles/${MY_P}.tar.gz"
+
+LICENSE="Qu-Prolog GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86"
+IUSE="debug doc examples pedro qt4 readline threads"
+
+RDEPEND="
+	!dev-util/mpatch
+	!dev-util/rej
+	qt4? ( dev-qt/qtgui:4 )
+	pedro? ( net-misc/pedro )
+	readline? ( app-misc/rlwrap )"
+DEPEND="${RDEPEND}
+	dev-lang/perl"
+
+S="${WORKDIR}"/${MY_P}
+
+src_prepare() {
+	epatch \
+		"${FILESDIR}"/${P}-portage.patch \
+		"${FILESDIR}"/${P}-cflags.patch
+}
+
+src_configure() {
+	econf \
+		--libdir=/usr/$(get_libdir) \
+		$(use_enable debug) \
+		$(use_enable threads multiple-threads)
+
+	if use qt4; then
+		cd "${S}"/src/xqp || die
+		eqmake4 xqp.pro
+	fi
+}
+
+src_compile() {
+	emake
+
+	if use qt4; then
+		cd "${S}"/src/xqp || die
+		emake
+	fi
+}
+
+src_install() {
+	sed \
+		-e "s|${S}|/usr/$(get_libdir)/qu-prolog|g" \
+		-i bin/qc bin/qc1.qup bin/qecat bin/qg bin/qp || die
+
+	dobin bin/{qa,qdeal,qem,ql,qc,qc1.qup,qecat,qg,qp,qppp,kq}
+
+	use qt4 && dobin src/xqp/xqp
+
+	insinto /usr/$(get_libdir)/${PN}/bin
+	doins bin/rl_commands
+	doins bin/{qc1.qup,qecat,qg,qp}.qx
+
+	insinto /usr/$(get_libdir)/${PN}/library
+	doins prolog/library/*.qo
+
+	insinto /usr/$(get_libdir)/${PN}/compiler
+	doins prolog/compiler/*.qo
+
+	doman doc/man/man1/*.1
+
+	dodoc README
+
+	if use doc ; then
+		docinto reference-manual
+		dodoc doc/manual/*.html
+		docinto user-guide
+		dodoc doc/user/main.pdf
+	fi
+
+	if use examples ; then
+		insinto /usr/share/doc/${PF}/examples
+		doins examples/*.ql
+		docinto examples
+		newdoc examples/README README.examples
+	fi
+}