dev-lang/swi-prolog: bump development version

Package-Manager: Portage-3.0.4, Repoman-2.3.22
Signed-off-by: Keri Harris <keri@gentoo.org>

2 files changed, 105 insertions, 0 deletions

diff --git a/dev-lang/swi-prolog/Manifest b/dev-lang/swi-prolog/Manifest
index 731f1eac5d28..fc84942effb3 100644
--- a/dev-lang/swi-prolog/Manifest
+++ b/dev-lang/swi-prolog/Manifest
@@ -7,3 +7,4 @@ DIST swipl-8.2.3.tar.gz 10999577 BLAKE2B 57cfa9f6fb97f0136a35da1850c7ae8da123d1c
 DIST swipl-8.3.12.tar.gz 11099881 BLAKE2B adbf262457e96371f29e2e002fc5e0e927a417259e57e722334481ce16284a19e850cb3d4bac7696140645a80b1257d1210643900d79deeb9b3abbe5cf39da6e SHA512 30e0d0db70bdca2457a629046db571d17a4b25c705f56c8077f5798ffac9a62020f472165ede7aec0be68a0bcaf71d787108452505fe3fa30ff894445a37882a
 DIST swipl-8.3.13.tar.gz 11099911 BLAKE2B 6153c7d19f8626b1786d63c5fa2cd52299d51e1ab0d859f21aa9d298d57b8e8a193a0fbddb12b69fb92f1d41c7183cfa98615c3265967b24e529dbe312dbdfae SHA512 e0e05883a6c2c592c08bfd8142593e47427d7a48cdfaa8c92556749c4de10eef7807d273b66862541109f60764dcd67378ac7fa3781ac4b23e3e916b269d362d
 DIST swipl-8.3.14.tar.gz 11107292 BLAKE2B b97797ed36ec80336c43b35bfee02dd144e195d03b76781c5c4dc6f8ea69b28d0876c62a38c7c66eaae2ae4cfefba409bafd3d9b93cd1d306875eb5e32d657d3 SHA512 931bb8f76836a1e4acb89070e9a8e17332ae4ed21da12a557329fc90adac052d9c5b48f553589ae9e3aa2ff5ec710ffa69e83ccbb492cf7adfb83e7cc97c61b8
+DIST swipl-8.3.15.tar.gz 11117063 BLAKE2B 17a083e76b850cb94b5a482011256c4812c4fc1d86642cd1a0f70704d5ffc9fef5cfd63bddfab2330b26d67dc6ca640012cfdd0b82c2cc90aff04b82c644f7d4 SHA512 4c2daf9c635cee30d62006b299d9f373fdd1be044fda5363995fd7343ae18ec1173d268cbd8ece52dd275ab1ca75168b386ba247f77707248c24e3ab7bcc7563
diff --git a/dev-lang/swi-prolog/swi-prolog-8.3.15.ebuild b/dev-lang/swi-prolog/swi-prolog-8.3.15.ebuild
new file mode 100644
index 000000000000..c9064992abbc
--- /dev/null
+++ b/dev-lang/swi-prolog/swi-prolog-8.3.15.ebuild
@@ -0,0 +1,104 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake-utils eutils flag-o-matic multilib
+
+PATCHSET_VER="0"
+
+DESCRIPTION="versatile implementation of the Prolog programming language"
+HOMEPAGE="http://www.swi-prolog.org/"
+SRC_URI="http://www.swi-prolog.org/download/devel/src/swipl-${PV}.tar.gz"
+
+LICENSE="BSD-2"
+SLOT="0"
+KEYWORDS="~amd64 ~ppc ~x86 ~amd64-linux ~x86-linux ~ppc-macos"
+IUSE="archive berkdb debug doc +gmp java +libedit libressl minimal odbc pcre qt5 readline ssl test uuid X yaml"
+RESTRICT="!test? ( test )"
+
+RDEPEND="sys-libs/ncurses:=
+	sys-libs/zlib
+	archive? ( app-arch/libarchive )
+	berkdb? ( >=sys-libs/db-4:= )
+	odbc? ( dev-db/unixODBC )
+	pcre? ( dev-libs/libpcre )
+	readline? ( sys-libs/readline:= )
+	libedit? ( dev-libs/libedit )
+	gmp? ( dev-libs/gmp:0 )
+	ssl? (
+		!libressl? ( dev-libs/openssl:0 )
+		libressl? ( dev-libs/libressl )
+	)
+	java? ( >=virtual/jdk-1.7:= )
+	uuid? ( dev-libs/ossp-uuid )
+	qt5? (
+		dev-qt/qtwidgets:5
+		dev-qt/qtgui:5
+	)
+	X? (
+		virtual/jpeg:0
+		x11-libs/libX11
+		x11-libs/libXft
+		x11-libs/libXinerama
+		x11-libs/libXpm
+		x11-libs/libXt
+		x11-libs/libICE
+		x11-libs/libSM )
+	yaml? ( dev-libs/libyaml )"
+
+DEPEND="${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	java? ( test? ( =dev-java/junit-3.8* ) )"
+
+S="${WORKDIR}/swipl-${PV}"
+BUILD_DIR="${S}/build"
+CMAKE_USE_DIR="${S}"
+
+src_prepare() {
+	if [[ -d "${WORKDIR}"/${PV} ]] ; then
+		eapply "${WORKDIR}"/${PV}
+	fi
+	eapply_user
+
+	sed -i -e "s|\(SWIPL_INSTALL_PREFIX\)   lib/.*)|\1   $(get_libdir)/swipl)|" CMakeLists.txt || die
+	sed -i -e "s|\(SWIPL_INSTALL_CMAKE_CONFIG_DIR\) lib/|\1   $(get_libdir)/|" CMakeLists.txt || die
+
+	cmake-utils_src_prepare
+}
+
+src_configure() {
+	append-flags -fno-strict-aliasing
+	use debug && append-flags -DO_DEBUG
+
+	mycmakeargs=(
+		-DSWIPL_INSTALL_PREFIX=$(get_libdir)/swipl
+		-DUSE_GMP=$(usex gmp)
+		-DINSTALL_DOCUMENTATION=$(use doc && usex archive)
+		-DSWIPL_PACKAGES_BASIC=$(usex !minimal)
+		-DSWIPL_PACKAGES_ARCHIVE=$(usex archive)
+		-DSWIPL_PACKAGES_ODBC=$(usex odbc)
+		-DSWIPL_PACKAGES_BDB=$(usex berkdb)
+		-DSWIPL_PACKAGES_PCRE=$(usex pcre)
+		-DSWIPL_PACKAGES_YAML=$(usex yaml)
+		-DSWIPL_PACKAGES_SSL=$(usex ssl)
+		-DSWIPL_PACKAGES_JAVA=$(usex java)
+		-DSWIPL_PACKAGES_QT=$(usex qt5)
+		-DSWIPL_PACKAGES_X=$(usex X)
+		-DSWIPL_PACKAGES_TERM=$(if use libedit || use readline; then echo yes; else echo no; fi)
+		)
+
+	cmake-utils_src_configure
+}
+
+src_compile() {
+	XDG_CONFIG_DIRS="${HOME}" \
+	XDG_DATA_DIRS="${HOME}" \
+		cmake-utils_src_compile
+}
+
+src_test() {
+	USE_PUBLIC_NETWORK_TESTS=false \
+	USE_ODBC_TESTS=false \
+		cmake-utils_src_test -V
+}