dev-libs/OpenNI2: min java 1.8

Bug: https://bugs.gentoo.org/787356
Package-Manager: Portage-3.0.20, Repoman-3.0.2
Signed-off-by: Volkmar W. Pogatzki <gentoo@pogatzki.net>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

2 files changed, 115 insertions, 9 deletions

diff --git a/dev-libs/OpenNI2/OpenNI2-2.2_beta2-r1.ebuild b/dev-libs/OpenNI2/OpenNI2-2.2_beta2-r1.ebuild
new file mode 100644
index 000000000000..8650fe294537
--- /dev/null
+++ b/dev-libs/OpenNI2/OpenNI2-2.2_beta2-r1.ebuild
@@ -0,0 +1,102 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+SCM=""
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SCM="git-r3"
+	EGIT_REPO_URI="https://github.com/occipital/openni2"
+fi
+
+inherit ${SCM} toolchain-funcs multilib java-pkg-opt-2 flag-o-matic
+
+if [ "${PV#9999}" != "${PV}" ] ; then
+	SRC_URI=""
+else
+	KEYWORDS="~amd64 ~arm"
+	SRC_URI="https://github.com/occipital/OpenNI2/archive/${PV/_/-}.tar.gz -> ${P}.tar.gz"
+	S="${WORKDIR}/${P/_/-}"
+fi
+
+DESCRIPTION="OpenNI2 SDK"
+HOMEPAGE="https://structure.io/openni"
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="doc java neon opengl static-libs"
+
+RDEPEND="
+	virtual/libusb:1
+	virtual/libudev
+	virtual/jpeg:0
+	opengl? ( media-libs/freeglut )
+	java? ( virtual/jre:1.8 )
+"
+DEPEND="${RDEPEND}
+	doc? ( app-doc/doxygen )
+	java? ( virtual/jdk:1.8 )"
+
+PATCHES=(
+	"${FILESDIR}/jpeg.patch"
+	"${FILESDIR}/rpath.patch"
+	"${FILESDIR}/soname.patch"
+	"${FILESDIR}/pthread.patch"
+	"${FILESDIR}/c++14.patch"
+)
+
+src_prepare() {
+	default
+
+	rm -rf ThirdParty/LibJPEG
+	for i in ThirdParty/PSCommon/BuildSystem/Platform.* ; do
+		echo "" > ${i}
+	done
+}
+
+src_compile() {
+	use neon && export CFLAGS="${CFLAGS} -DXN_NEON"
+	emake \
+		CC="$(tc-getCC)" \
+		CXX="$(tc-getCXX)" \
+		ALLOW_WARNINGS=1 \
+		GLUT_SUPPORTED="$(usex opengl 1 0)" \
+		$(usex java "" ALL_WRAPPERS="") \
+		$(usex java "" JAVA_SAMPLES="")
+
+	if use doc ; then
+		cd "${S}/Source/Documentation"
+		doxygen || die
+	fi
+}
+
+src_install() {
+	dolib.so "${S}/Bin/"*Release/*.so
+	cp -a "${S}/Bin/"*Release/OpenNI2 "${ED}/usr/$(get_libdir)"
+
+	use static-libs && dolib.a "${S}/Bin/"*Release/*.a
+
+	insinto /usr/include/openni2
+	doins -r Include/*
+
+	dobin "${S}/Bin/"*Release/{PS1080Console,PSLinkConsole,SimpleRead,EventBasedRead,MultipleStreamRead,MWClosestPointApp}
+	use opengl && dobin "${S}/Bin/"*Release/{NiViewer,SimpleViewer,MultiDepthViewer,ClosestPointViewer}
+
+	if use java ; then
+		java-pkg_dojar "${S}/Bin/"*Release/*.jar
+		echo "java -jar ${JAVA_PKG_JARDEST}/org.openni.Samples.SimpleViewer.jar" > org.openni.Samples.SimpleViewer
+		dobin org.openni.Samples.SimpleViewer
+	fi
+
+	dodoc CHANGES.txt NOTICE README ReleaseNotes.txt Source/Documentation/Text/*.txt
+
+	if use doc ; then
+		docinto html
+		dodoc -r "${S}/Source/Documentation/html/"*
+	fi
+
+	dodir /usr/$(get_libdir)/pkgconfig
+	sed \
+		-e "s/@libdir@/$(get_libdir)/" \
+		-e "s/@version@/${PV}/" \
+		"${FILESDIR}/libopenni2.pc.in" > "${ED}/usr/$(get_libdir)/pkgconfig/libopenni2.pc" || die
+}
diff --git a/dev-libs/OpenNI2/OpenNI2-9999.ebuild b/dev-libs/OpenNI2/OpenNI2-9999.ebuild
index 13ff01010ca9..210a3efeea3a 100644
--- a/dev-libs/OpenNI2/OpenNI2-9999.ebuild
+++ b/dev-libs/OpenNI2/OpenNI2-9999.ebuild
@@ -1,7 +1,7 @@
 # Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
+EAPI=7
 
 SCM=""
 if [ "${PV#9999}" != "${PV}" ] ; then
@@ -9,7 +9,7 @@ if [ "${PV#9999}" != "${PV}" ] ; then
 	EGIT_REPO_URI="https://github.com/occipital/openni2"
 fi
 
-inherit ${SCM} toolchain-funcs epatch multilib java-pkg-opt-2 flag-o-matic
+inherit ${SCM} toolchain-funcs multilib java-pkg-opt-2 flag-o-matic
 
 if [ "${PV#9999}" != "${PV}" ] ; then
 	SRC_URI=""
@@ -30,17 +30,20 @@ RDEPEND="
 	virtual/libudev
 	virtual/jpeg:0
 	opengl? ( media-libs/freeglut )
-	java? ( >=virtual/jre-1.5:* )
+	java? ( virtual/jre:1.8 )
 "
 DEPEND="${RDEPEND}
 	doc? ( app-doc/doxygen )
-	java? ( >=virtual/jdk-1.5:* )"
+	java? ( virtual/jdk:1.8 )"
+
+PATCHES=(
+	"${FILESDIR}/jpeg.patch"
+	"${FILESDIR}/rpath.patch"
+	"${FILESDIR}/soname.patch"
+)
 
 src_prepare() {
-	epatch \
-		"${FILESDIR}/jpeg.patch" \
-		"${FILESDIR}/rpath.patch" \
-		"${FILESDIR}/soname.patch"
+	default
 
 	rm -rf ThirdParty/LibJPEG
 	for i in ThirdParty/PSCommon/BuildSystem/Platform.* ; do
@@ -85,7 +88,8 @@ src_install() {
 	dodoc CHANGES.txt NOTICE README.md ReleaseNotes.txt Source/Documentation/Text/*.txt
 
 	if use doc ; then
-		dohtml -r "${S}/Source/Documentation/html/"*
+		docinto html
+		dodoc -r "${S}/Source/Documentation/html/"*
 	fi
 
 	dodir /usr/$(get_libdir)/pkgconfig