dev-libs/aws-c-io: Version Bump to 0.9.2

Package-Manager: Portage-3.0.17, Repoman-3.0.2
Signed-off-by: Sven Eden <sven.eden@prydeworx.com>
Signed-off-by: Joonas Niilola <juippis@gentoo.org>

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-libs/aws-c-io/aws-c-io-0.9.2.ebuild b/dev-libs/aws-c-io/aws-c-io-0.9.2.ebuild
new file mode 100644
index 000000000000..c36b3f45da8b
--- /dev/null
+++ b/dev-libs/aws-c-io/aws-c-io-0.9.2.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+inherit cmake
+
+DESCRIPTION="AWS SDK for C module, handles IO and TLS work for application protocols"
+HOMEPAGE="https://github.com/awslabs/aws-c-io"
+SRC_URI="https://github.com/awslabs/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="static-libs test"
+
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	>=dev-libs/aws-c-cal-0.4.5:=[static-libs=]
+	>=dev-libs/aws-c-common-0.5.2:=[static-libs=]
+	>=dev-libs/s2n-0.10.21:=[static-libs=]
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-0.7.0-cmake-prefix.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DBUILD_SHARED_LIBS=$(usex !static-libs)
+		-DBUILD_TESTING=$(usex test)
+	)
+
+	if use test; then
+		# (#759802) Due to network sandboxing of portage, internet connectivity
+		# tests will always fail. If you need a USE flag, because you want/need
+		# to perform these tests manually, please open a bug report for it.
+		mycmakeargs+=(
+			-DENABLE_NET_TESTS=OFF
+		)
+	fi
+
+	cmake_src_configure
+}