dev-libs/device-atlas-api-c: Version bump

Closes: https://github.com/gentoo/gentoo/pull/6784
Package-Manager: Portage-2.3.13, Repoman-2.3.3

1 files changed, 50 insertions, 0 deletions

diff --git a/dev-libs/device-atlas-api-c/device-atlas-api-c-2.1.3.ebuild b/dev-libs/device-atlas-api-c/device-atlas-api-c-2.1.3.ebuild
new file mode 100644
index 000000000000..4679d064f462
--- /dev/null
+++ b/dev-libs/device-atlas-api-c/device-atlas-api-c-2.1.3.ebuild
@@ -0,0 +1,50 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+inherit cmake-multilib
+
+MY_P="deviceatlas-enterprise-c-${PV/_p/_}"
+
+DESCRIPTION="API to detect devices based on the User-Agent HTTP header"
+HOMEPAGE="https://deviceatlas.com"
+SRC_URI="${MY_P}.tgz"
+
+LICENSE="all-rights-reserved"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~ppc ~x86"
+IUSE="doc examples"
+
+RDEPEND="dev-libs/libpcre[${MULTILIB_USEDEP}]"
+DEPEND="
+	${RDEPEND}"
+
+RESTRICT="fetch mirror bindist"
+
+S="${WORKDIR}/${MY_P}"
+
+PATCHES=(
+	"${FILESDIR}/${PV}-src-cmakelists.patch"
+)
+
+pkg_nofetch() {
+	eerror "Please go to https://deviceatlas.com/deviceatlas-haproxy-module"
+	eerror "And download DeviceAtlas C API"
+	eerror "Then place the file in ${DISTDIR}/${MY_P}.tgz"
+}
+
+multilib_src_install_all() {
+	if use doc; then
+		local -a HTML_DOCS=( Documentation )
+	fi
+
+	if use examples; then
+		docinto examples
+		dodoc Examples/daexutil.h
+		dodoc Examples/example{0,1,2,3,4}.c
+		dodoc Examples/util.c
+		dodoc Examples/EXAMPLES.USAGE
+	fi
+
+	einstalldocs
+}