proj/gentoo: Initial commit

This commit represents a new era for Gentoo:
Storing the gentoo-x86 tree in Git, as converted from CVS.

This commit is the start of the NEW history.
Any historical data is intended to be grafted onto this point.

Creation process:
1. Take final CVS checkout snapshot
2. Remove ALL ChangeLog* files
3. Transform all Manifests to thin
4. Remove empty Manifests
5. Convert all stale $Header$/$Id$ CVS keywords to non-expanded Git $Id$
5.1. Do not touch files with -kb/-ko keyword flags.

Signed-off-by: Robin H. Johnson <robbat2@gentoo.org>
X-Thanks: Alec Warner <antarus@gentoo.org> - did the GSoC 2006 migration tests
X-Thanks: Robin H. Johnson <robbat2@gentoo.org> - infra guy, herding this project
X-Thanks: Nguyen Thai Ngoc Duy <pclouds@gentoo.org> - Former Gentoo developer, wrote Git features for the migration
X-Thanks: Brian Harring <ferringb@gentoo.org> - wrote much python to improve cvs2svn
X-Thanks: Rich Freeman <rich0@gentoo.org> - validation scripts
X-Thanks: Patrick Lauer <patrick@gentoo.org> - Gentoo dev, running new 2014 work in migration
X-Thanks: Michał Górny <mgorny@gentoo.org> - scripts, QA, nagging
X-Thanks: All of other Gentoo developers - many ideas and lots of paint on the bikeshed

1 files changed, 66 insertions, 0 deletions

diff --git a/dev-libs/libappindicator/libappindicator-12.10.0-r300.ebuild b/dev-libs/libappindicator/libappindicator-12.10.0-r300.ebuild
new file mode 100644
index 000000000000..e334366c9572
--- /dev/null
+++ b/dev-libs/libappindicator/libappindicator-12.10.0-r300.ebuild
@@ -0,0 +1,66 @@
+# Copyright 1999-2015 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+# $Id$
+
+EAPI=5
+VALA_MIN_API_VERSION="0.16"
+VALA_USE_DEPEND="vapigen"
+
+inherit autotools eutils multilib-minimal vala
+
+DESCRIPTION="A library to allow applications to export a menu into the Unity Menu bar"
+HOMEPAGE="http://launchpad.net/libappindicator"
+SRC_URI="http://launchpad.net/${PN}/${PV%.*}/${PV}/+download/${P}.tar.gz"
+
+LICENSE="LGPL-2.1 LGPL-3"
+SLOT="3"
+KEYWORDS="~amd64 ~x86"
+IUSE="+introspection"
+
+RDEPEND="
+	>=dev-libs/dbus-glib-0.98[${MULTILIB_USEDEP}]
+	>=dev-libs/glib-2.26:2[${MULTILIB_USEDEP}]
+	>=dev-libs/libdbusmenu-0.6.2[gtk3,${MULTILIB_USEDEP}]
+	>=dev-libs/libindicator-12.10.0:3[${MULTILIB_USEDEP}]
+	>=x11-libs/gtk+-3.2:3[${MULTILIB_USEDEP},introspection?]
+	introspection? ( >=dev-libs/gobject-introspection-1 )
+"
+DEPEND="${RDEPEND}
+	virtual/pkgconfig[${MULTILIB_USEDEP}]
+	introspection? ( $(vala_depend) )
+"
+
+src_prepare() {
+	# Don't use -Werror
+	sed -i -e 's/ -Werror//' {src,tests}/Makefile.{am,in} || die
+
+	epatch "${FILESDIR}"/${P}-conditional-py-bindings.patch
+	eautoreconf
+
+	# Disable MONO for now because of http://bugs.gentoo.org/382491
+	sed -i -e '/^MONO_REQUIRED_VERSION/s:=.*:=9999:' configure || die
+}
+
+multilib_src_configure() {
+	if multilib_is_native_abi; then
+		local -x VALAC VAPIGEN_VAPIDIR PKG_CONFIG_PATH
+		use introspection && vala_src_prepare
+	fi
+
+	ECONF_SOURCE=${S} \
+	econf \
+		--disable-silent-rules \
+		--disable-static \
+		--with-gtk=3 \
+		$(multilib_native_use_enable introspection)
+}
+
+multilib_src_install() {
+	emake -j1 DESTDIR="${D}" install
+}
+
+multilib_src_install_all() {
+	dodoc AUTHORS ChangeLog
+
+	prune_libtool_files
+}