dev-libs/libgit2-glib: Bump to 0.26.2

1 files changed, 58 insertions, 0 deletions

diff --git a/dev-libs/libgit2-glib/libgit2-glib-0.26.2.ebuild b/dev-libs/libgit2-glib/libgit2-glib-0.26.2.ebuild
new file mode 100644
index 000000000000..2a3ed8af6ae2
--- /dev/null
+++ b/dev-libs/libgit2-glib/libgit2-glib-0.26.2.ebuild
@@ -0,0 +1,58 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+PYTHON_COMPAT=( python{3_4,3_5,3_6} )
+VALA_USE_DEPEND="vapigen"
+
+inherit gnome2 python-r1 vala
+
+DESCRIPTION="Git library for GLib"
+HOMEPAGE="https://wiki.gnome.org/Projects/Libgit2-glib"
+
+LICENSE="LGPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+
+IUSE="python +ssh +vala"
+REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
+
+# Specify libgit2 dependency with subslot because libgit2 upstream has a habit
+# of changing their API in each release in ways that break libgit2-glib
+RDEPEND="
+	>=dev-libs/gobject-introspection-0.10.1:=
+	>=dev-libs/glib-2.44.0:2
+	>=dev-libs/libgit2-0.26.0:0/26[ssh?]
+	python? (
+		${PYTHON_DEPS}
+		dev-python/pygobject:3[${PYTHON_USEDEP}] )
+"
+DEPEND="${RDEPEND}
+	>=dev-util/gtk-doc-am-1.11
+	virtual/pkgconfig
+	vala? ( $(vala_depend) )
+"
+
+src_prepare() {
+	use vala && vala_src_prepare
+	gnome2_src_prepare
+}
+
+src_configure() {
+	gnome2_src_configure \
+		$(use_enable python) \
+		$(use_enable ssh) \
+		$(use_enable vala)
+}
+
+src_install() {
+	gnome2_src_install
+
+	if use python ; then
+		install_gi_override() {
+			python_moduleinto "$(python_get_sitedir)/gi/overrides"
+			python_domodule "${S}"/${PN}/Ggit.py
+		}
+		python_foreach_impl install_gi_override
+	fi
+}