dev-libs/libindicator: update EAPI 5 -> 7 in :2

Signed-off-by: Sam James <sam@gentoo.org>

1 files changed, 28 insertions, 15 deletions

diff --git a/dev-libs/libindicator/libindicator-12.10.1-r201.ebuild b/dev-libs/libindicator/libindicator-12.10.1-r201.ebuild
index 24ca42f49f2e..f470b6ff84b5 100644
--- a/dev-libs/libindicator/libindicator-12.10.1-r201.ebuild
+++ b/dev-libs/libindicator/libindicator-12.10.1-r201.ebuild
@@ -1,8 +1,9 @@
-# Copyright 1999-2020 Gentoo Authors
+# Copyright 1999-2021 Gentoo Authors
 # Distributed under the terms of the GNU General Public License v2
 
-EAPI=5
-inherit autotools eutils flag-o-matic ltprune virtualx multilib-minimal
+EAPI=7
+
+inherit autotools flag-o-matic virtualx multilib-minimal
 
 DESCRIPTION="A set of symbols and convience functions that all indicators would like to use"
 HOMEPAGE="https://launchpad.net/libindicator"
@@ -14,31 +15,41 @@ KEYWORDS="amd64 ~arm x86"
 IUSE="test"
 RESTRICT="!test? ( test )"
 
-RDEPEND=">=dev-libs/glib-2.22[${MULTILIB_USEDEP}]
-	>=x11-libs/gtk+-2.18:2[${MULTILIB_USEDEP}]"
-DEPEND="${RDEPEND}
+RDEPEND="
+	>=dev-libs/glib-2.22[${MULTILIB_USEDEP}]
+	>=x11-libs/gtk+-2.18:2[${MULTILIB_USEDEP}]
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
 	dev-util/glib-utils
 	virtual/pkgconfig
-	test? ( dev-util/dbus-test-runner )"
+	test? ( dev-util/dbus-test-runner )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-ldflags-spacing.patch
+)
 
 src_prepare() {
-	epatch "${FILESDIR}"/${PN}-ldflags-spacing.patch
+	default
+
 	eautoreconf
 }
 
 multilib_src_configure() {
 	append-flags -Wno-error
 
-	myconf=(
+	local myconf=(
 		--disable-static
 		--with-gtk=2
 	)
-	local ECONF_SOURCE=${S}
-	econf "${myconf[@]}"
+
+	ECONF_SOURCE="${S}" econf "${myconf[@]}"
 }
 
 multilib_src_test() {
-	Xemake check #391179
+	# bug #391179
+	Xemake check
 }
 
 multilib_src_install() {
@@ -46,10 +57,12 @@ multilib_src_install() {
 }
 
 multilib_src_install_all() {
-	einstalldocs
-	prune_libtool_files --all
+	default
+
+	find "${ED}" -name '*.la' -delete || die
 
 	rm -vf \
 		"${ED}"/usr/lib*/libdummy-indicator-* \
-		"${ED}"/usr/share/${PN}/*indicator-debugging
+		"${ED}"/usr/share/${PN}/*indicator-debugging \
+		|| die
 }