dev-libs/libinput: Bump to version 1.19.3

Signed-off-by: Lars Wendler <polynomial-c@gentoo.org>

2 files changed, 89 insertions, 0 deletions

diff --git a/dev-libs/libinput/Manifest b/dev-libs/libinput/Manifest
index 060c8e4f89bb..8c9c077ce39e 100644
--- a/dev-libs/libinput/Manifest
+++ b/dev-libs/libinput/Manifest
@@ -1 +1,2 @@
 DIST libinput-1.19.2.tar.xz 654924 BLAKE2B b55d34186bba3d4956d7308594acd0928b7bc575c34b8c53ee95780887beccd141804e278cd1ea6c8fb48d064bde9c95c26c6613d6169dfa4e7ccdd64a50d3e3 SHA512 fc5244dc90ceb710f7b5bb76a3cafc7dd5a8d5fa05c51122412615bfc3a99435d6a1017b79c3ce73561139fc2f5959acaf16cb9500796ea2f3eb6cb95d1a1acb
+DIST libinput-1.19.3.tar.xz 655164 BLAKE2B a07d91603a3d4e759aad25ee46b11dbee47eb013a2361f1b70acd616fee0ed9660e6fa8773948d6acf3686179fd7aaf76bf8285f3dc3137a4b1b605ec0e4d6d2 SHA512 f4b776d0da78c687ba21b430a04941ac6b43f68970c82ec9f7360358fdea5ed6a873948ce66a25bcdd64d4b95fa4bf705cc24dbc25c7c0f5fd2d0efbd763f298
diff --git a/dev-libs/libinput/libinput-1.19.3.ebuild b/dev-libs/libinput/libinput-1.19.3.ebuild
new file mode 100644
index 000000000000..07b92e48c6a0
--- /dev/null
+++ b/dev-libs/libinput/libinput-1.19.3.ebuild
@@ -0,0 +1,88 @@
+# Copyright 2014-2021 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+PYTHON_COMPAT=( python3_{8..10} )
+
+inherit meson python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
+SRC_URI="https://www.freedesktop.org/software/${PN}/${P}.tar.xz"
+
+LICENSE="MIT"
+SLOT="0/10"
+[[ "$(ver_cut 3)" -gt 900 ]] || \
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="doc input_devices_wacom test"
+RESTRICT="!test? ( test )"
+
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/commonmark[${PYTHON_USEDEP}]
+			dev-python/recommonmark[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			>=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]
+		')
+		>=app-doc/doxygen-1.8.3
+		>=media-gfx/graphviz-2.38.0
+	)
+"
+#	test? ( dev-util/valgrind )
+RDEPEND="
+	input_devices_wacom? ( >=dev-libs/libwacom-0.27 )
+	>=dev-libs/libevdev-1.9.902
+	>=sys-libs/mtdev-1.1
+	virtual/libudev:=
+	virtual/udev
+"
+DEPEND="${RDEPEND}
+	test? ( >=dev-libs/check-0.9.10 )"
+
+python_check_deps() {
+	has_version -b "dev-python/commonmark[${PYTHON_USEDEP}]" && \
+	has_version -b "dev-python/recommonmark[${PYTHON_USEDEP}]" && \
+	has_version -b "dev-python/sphinx[${PYTHON_USEDEP}]" && \
+	has_version -b ">=dev-python/sphinx_rtd_theme-0.2.4[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_prepare() {
+	default
+	sed "s@, '-Werror'@@" -i meson.build || die #744250
+}
+
+src_configure() {
+	# gui can be built but will not be installed
+	local emesonargs=(
+		-Ddebug-gui=false
+		$(meson_use doc documentation)
+		$(meson_use input_devices_wacom libwacom)
+		$(meson_use test tests)
+		-Dudev-dir="${EPREFIX}$(get_udevdir)"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use doc ; then
+		docinto html
+		dodoc -r "${BUILD_DIR}"/Documentation/.
+	fi
+}
+
+pkg_postinst() {
+	pkgname="dev-python/python-libevdev"
+	if [[ -z "${REPLACING_VERSIONS}" ]] && ! has_version "${pkgname}" ; then
+		einfo "${pkgname} must be installed to use the"
+		einfo "libinput measure and libinput replay tools."
+	fi
+
+	udevadm hwdb --update --root="${ROOT}"
+}