dev-libs/libressl: version bump to 2.6.4

Package-Manager: Portage-2.3.13, Repoman-2.3.3

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-libs/libressl/libressl-2.6.4.ebuild b/dev-libs/libressl/libressl-2.6.4.ebuild
new file mode 100644
index 000000000000..22abf48a53e9
--- /dev/null
+++ b/dev-libs/libressl/libressl-2.6.4.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit eutils multilib-minimal
+
+DESCRIPTION="Free version of the SSL/TLS protocol forked from OpenSSL"
+HOMEPAGE="http://www.libressl.org/"
+SRC_URI="http://ftp.openbsd.org/pub/OpenBSD/LibreSSL/${P}.tar.gz"
+
+LICENSE="ISC openssl"
+# Reflects ABI of libcrypto.so and libssl.so.  Since these can differ,
+# we'll try to use the max of either.  However, if either change between
+# versions, we have to change the subslot to trigger rebuild of consumers.
+SLOT="0/44"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="+asm static-libs"
+
+RDEPEND="!dev-libs/openssl:0"
+DEPEND="${RDEPEND}"
+PDEPEND="app-misc/ca-certificates"
+
+src_prepare() {
+	touch crypto/Makefile.in
+
+	sed -i \
+		-e '/^[ \t]*CFLAGS=/s#-g ##' \
+		-e '/^[ \t]*CFLAGS=/s#-g"#"#' \
+		-e '/^[ \t]*CFLAGS=/s#-O2 ##' \
+		-e '/^[ \t]*CFLAGS=/s#-O2"#"#' \
+		-e '/^[ \t]*USER_CFLAGS=/s#-O2 ##' \
+		-e '/^[ \t]*USER_CFLAGS=/s#-O2"#"#' \
+		configure || die "fixing CFLAGS failed"
+
+	eapply_user
+}
+
+multilib_src_configure() {
+	ECONF_SOURCE="${S}" econf \
+		$(use_enable asm) \
+		$(use_enable static-libs static)
+}
+
+multilib_src_test() {
+	emake check
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	prune_libtool_files
+}