dev-libs/libsass: version bump to 3.4.8

Package-Manager: Portage-2.3.20, Repoman-2.3.6

1 files changed, 54 insertions, 0 deletions

diff --git a/dev-libs/libsass/libsass-3.4.8.ebuild b/dev-libs/libsass/libsass-3.4.8.ebuild
new file mode 100644
index 000000000000..78b45f223a4e
--- /dev/null
+++ b/dev-libs/libsass/libsass-3.4.8.ebuild
@@ -0,0 +1,54 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+inherit autotools eutils ltprune multilib-minimal
+
+if [[ ${PV} = *9999 ]]; then
+	EGIT_REPO_URI="https://github.com/sass/libsass.git"
+	inherit git-r3
+	KEYWORDS=
+else
+	SRC_URI="https://github.com/sass/libsass/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~x86 ~amd64-linux"
+fi
+
+DESCRIPTION="A C/C++ implementation of a Sass CSS compiler"
+HOMEPAGE="https://github.com/sass/libsass"
+LICENSE="MIT"
+SLOT="0/0" # libsass soname
+IUSE="static-libs"
+
+RDEPEND=""
+DEPEND="${RDEPEND}"
+
+DOCS=( Readme.md SECURITY.md )
+
+src_prepare() {
+	default
+
+	if [[ ${PV} != *9999 ]]; then
+		[[ -f VERSION ]] || echo "${PV}" > VERSION
+	fi
+	eautoreconf
+
+	# only sane way to deal with various version-related scripts, env variables etc.
+	multilib_copy_sources
+}
+
+multilib_src_configure() {
+	econf \
+		$(use_enable static-libs static) \
+		--enable-shared
+}
+
+multilib_src_install() {
+	emake DESTDIR="${D}" install
+	prune_libtool_files
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	dodoc -r "${S}/docs"
+}