dev-libs/newt: version bump to 0.52.20 and bump to EAPI 6.

* Bump to upsream version 0.52.20.
* Convert to EAPI=6, which requires a small patch adjustment for -p1.
* Remove now-unused eutils inherit.
* Add 3.x to PYTHON_COMPAT since upstream added py3 support.
* Add :0 slot on ncurses dep.

Closes: https://bugs.gentoo.org/598904
Closes: https://github.com/gentoo/gentoo/pull/5738

1 files changed, 92 insertions, 0 deletions

diff --git a/dev-libs/newt/newt-0.52.20.ebuild b/dev-libs/newt/newt-0.52.20.ebuild
new file mode 100644
index 000000000000..c71f947af1b5
--- /dev/null
+++ b/dev-libs/newt/newt-0.52.20.ebuild
@@ -0,0 +1,92 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python{2_7,3_4,3_5,3_6} )
+
+inherit python-r1 multilib autotools toolchain-funcs
+
+DESCRIPTION="Redhat's Newt windowing toolkit development files"
+HOMEPAGE="https://fedorahosted.org/newt/"
+SRC_URI="https://fedorahosted.org/releases/n/e/newt/${P}.tar.gz"
+
+LICENSE="LGPL-2"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd"
+IUSE="gpm nls tcl"
+
+REQUIRED_USE="${PYTHON_REQUIRED_USE}"
+
+RDEPEND="${PYTHON_DEPS}
+	>=dev-libs/popt-1.6
+	=sys-libs/slang-2*
+	elibc_uclibc? ( sys-libs/ncurses:0= )
+	gpm? ( sys-libs/gpm )
+	tcl? ( >=dev-lang/tcl-8.5:0 )
+	"
+DEPEND="${RDEPEND}"
+
+src_prepare() {
+	# bug 73850
+	if use elibc_uclibc; then
+		sed -i -e 's:-lslang:-lslang -lncurses:g' Makefile.in || die
+	fi
+
+	sed -i Makefile.in \
+		-e 's|$(SHCFLAGS) -o|$(LDFLAGS) &|g' \
+		-e 's|-g -o|$(CFLAGS) $(LDFLAGS) -o|g' \
+		-e 's|-shared -o|$(CFLAGS) $(LDFLAGS) &|g' \
+		-e 's|instroot|DESTDIR|g' \
+		-e 's|	make |	$(MAKE) |g' \
+		-e "s|	ar |	$(tc-getAR) |g" \
+		|| die "sed Makefile.in"
+
+	local langs=""
+	if [ -n "${LINGUAS}" ]; then
+		for lang in ${LINGUAS}; do
+			test -r po/${lang}.po && langs="${langs} ${lang}.po"
+		done
+		sed -i po/Makefile \
+			-e "/^CATALOGS = /cCATALOGS = ${langs}" \
+			|| die "sed po/Makefile"
+	fi
+
+	eapply "${FILESDIR}"/${PN}-0.52.13-gold.patch \
+		"${FILESDIR}"/${PN}-0.52.14-tcl.patch \
+		"${FILESDIR}"/${PN}-0.52.15-makefile.patch
+	eapply_user
+	eautoreconf
+}
+
+src_configure() {
+	configuring() {
+		econf \
+			PYTHONVERS="${PYTHON}" \
+			$(use_with gpm gpm-support) \
+			$(use_with tcl) \
+			$(use_enable nls)
+	}
+	python_foreach_impl configuring
+}
+
+src_compile() {
+	building() {
+		emake PYTHONVERS="${EPYTHON}"
+	}
+	python_foreach_impl building
+}
+
+src_install() {
+	installit() {
+		emake \
+			DESTDIR="${D}" \
+			PYTHONVERS="${EPYTHON}" \
+			install
+		python_optimize
+	}
+	python_foreach_impl installit
+	dodoc peanuts.py popcorn.py tutorial.sgml
+	doman whiptail.1
+	einstalldocs
+}