dev-libs/opencl-clang: drop multilib, EAPI 7 -> 8

Since no packages depend on multilib, we can drop it.

Signed-off-by: Conrad Kostecki <conikost@gentoo.org>

1 files changed, 40 insertions, 0 deletions

diff --git a/dev-libs/opencl-clang/opencl-clang-13.0.0-r1.ebuild b/dev-libs/opencl-clang/opencl-clang-13.0.0-r1.ebuild
new file mode 100644
index 000000000000..a46a92527df9
--- /dev/null
+++ b/dev-libs/opencl-clang/opencl-clang-13.0.0-r1.ebuild
@@ -0,0 +1,40 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+LLVM_MAX_SLOT="13"
+
+inherit cmake llvm
+
+DESCRIPTION="OpenCL-oriented thin wrapper library around clang"
+HOMEPAGE="https://github.com/intel/opencl-clang"
+SRC_URI="https://github.com/intel/${PN}/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${PN}-${PV}"
+
+LICENSE="UoI-NCSA"
+SLOT="13"
+KEYWORDS="amd64"
+
+RDEPEND="
+	dev-util/spirv-llvm-translator:${SLOT}=
+	sys-devel/clang:${SLOT}=[static-analyzer]
+	sys-devel/llvm:${SLOT}=
+"
+
+DEPEND="${RDEPEND}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-8.0.0-clang_library_dir.patch
+	"${FILESDIR}"/${PN}-10.0.0.1_find-llvm-tblgen.patch
+	"${FILESDIR}"/${PN}-13.0.0_version.patch
+)
+
+src_configure() {
+	local mycmakeargs=(
+		-DCMAKE_INSTALL_PREFIX="$(get_llvm_prefix ${LLVM_MAX_SLOT})"
+		-DCLANG_LIBRARY_DIRS="${EPREFIX}"/usr/lib/clang
+	)
+
+	cmake_src_configure
+}