dev-libs/softhsm: version bump

Signed-off-by: Alon Bar-Lev <alonbl@gentoo.org>
Package-Manager: Portage-2.3.49, Repoman-2.3.11

1 files changed, 45 insertions, 0 deletions

diff --git a/dev-libs/softhsm/softhsm-2.5.0.ebuild b/dev-libs/softhsm/softhsm-2.5.0.ebuild
new file mode 100644
index 000000000000..aecd75f474e9
--- /dev/null
+++ b/dev-libs/softhsm/softhsm-2.5.0.ebuild
@@ -0,0 +1,45 @@
+# Copyright 1999-2018 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+DESCRIPTION="A software PKCS#11 implementation"
+HOMEPAGE="https://www.opendnssec.org/"
+SRC_URI="https://www.opendnssec.org/files/source/${P}.tar.gz"
+
+KEYWORDS="~alpha ~amd64 ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~sparc ~x86"
+IUSE="bindist libressl migration-tool test"
+SLOT="2"
+LICENSE="BSD"
+
+RDEPEND="migration-tool? ( dev-db/sqlite:3= )
+	!libressl? ( dev-libs/openssl:=[bindist=] )
+	libressl? ( dev-libs/libressl:= )
+	!~dev-libs/softhsm-2.0.0:0"
+DEPEND="${RDEPEND}"
+BDEPEND="virtual/pkgconfig
+	sys-devel/gcc:=[cxx]
+	test? ( dev-util/cppunit )"
+
+DOCS=(
+	NEWS
+	README.md
+)
+
+src_configure() {
+	econf \
+		--disable-static \
+		--with-crypto-backend=openssl \
+		--disable-p11-kit \
+		--localstatedir="${EROOT}/var" \
+		$(use_enable !bindist ecc) \
+		$(use_enable !libressl gost) \
+		$(use_with migration-tool migrate)
+}
+
+src_install() {
+	default
+	find "${D}" -name '*.la' -delete || die
+
+	keepdir "${EROOT}/var/lib/softhsm/tokens"
+}