dev-libs/weston: Version bump to 10.0.1

Signed-off-by: James Le Cuirot <chewi@gentoo.org>

2 files changed, 149 insertions, 0 deletions

diff --git a/dev-libs/weston/Manifest b/dev-libs/weston/Manifest
index ff35a7d9ebb6..54eb5f76e618 100644
--- a/dev-libs/weston/Manifest
+++ b/dev-libs/weston/Manifest
@@ -1 +1,2 @@
 DIST weston-10.0.0.tar.xz 1774600 BLAKE2B b2b8fa4f7542aba03970ca8abf504f340f8f8da9f9581c16ceac5c702eac355f5d4244778393a8804017f39dff490431e26a48580746033158bd2d2b721437f8 SHA512 77e05530751e4f743eebf015ab5b78a1fcc66b774713b5e296cfffc488be84e459f811c85ac4280b7b63eebf4ff5c958dd7306376ab343e6b80feae16c8c35a4
+DIST weston-10.0.1.tar.xz 1776740 BLAKE2B e672d3d7d87782162fd79778fb7dab1e81de688d33bc470bb3d151da991ac94e680903781a9d7d8130df6136931d0d2badacc6aede09c96094f9fc2698ea4545 SHA512 688d843096a95b463161b98e85ca3443b31ba2ee49fc8d456a2780cc96f576e9d097054e9f361997a66e9cc8373cf29e406a742dae3884b3b50b26acf1710c8c
diff --git a/dev-libs/weston/weston-10.0.1.ebuild b/dev-libs/weston/weston-10.0.1.ebuild
new file mode 100644
index 000000000000..8e4f335e1688
--- /dev/null
+++ b/dev-libs/weston/weston-10.0.1.ebuild
@@ -0,0 +1,148 @@
+# Copyright 1999-2022 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+if [[ ${PV} = 9999* ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/wayland/weston.git"
+	GIT_ECLASS="git-r3"
+	EXPERIMENTAL="true"
+fi
+
+PYTHON_COMPAT=( python3_{9..11} )
+inherit meson python-any-r1 readme.gentoo-r1 xdg-utils ${GIT_ECLASS}
+
+DESCRIPTION="Wayland reference compositor"
+HOMEPAGE="https://wayland.freedesktop.org/ https://gitlab.freedesktop.org/wayland/weston"
+
+if [[ ${PV} = *9999* ]]; then
+	SRC_URI="${SRC_PATCHES}"
+else
+	SRC_URI="https://gitlab.freedesktop.org/wayland/${PN}/-/releases/${PV}/downloads/${P}.tar.xz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~ia64 ~ppc ~ppc64 ~riscv ~sparc ~x86"
+fi
+
+LICENSE="MIT CC-BY-SA-3.0"
+SLOT="0"
+
+IUSE="colord +desktop +drm editor examples fbdev fullscreen +gles2 headless ivi jpeg kiosk lcms pipewire rdp remoting +resize-optimization screen-sharing +seatd +suid systemd test wayland-compositor webp +X xwayland"
+RESTRICT="!test? ( test )"
+
+REQUIRED_USE="
+	colord? ( lcms )
+	drm? ( gles2 )
+	pipewire? ( drm )
+	remoting? ( drm gles2 )
+	screen-sharing? ( rdp )
+	test? ( desktop headless xwayland )
+	wayland-compositor? ( gles2 )
+	|| ( drm fbdev headless rdp wayland-compositor X )
+"
+
+RDEPEND="
+	>=dev-libs/libinput-0.8.0
+	>=dev-libs/wayland-1.18.0
+	>=dev-libs/wayland-protocols-1.24
+	lcms? ( media-libs/lcms:2 )
+	media-libs/libpng:0=
+	webp? ( media-libs/libwebp:0= )
+	jpeg? ( media-libs/libjpeg-turbo:0= )
+	>=x11-libs/cairo-1.11.3
+	>=x11-libs/libdrm-2.4.95
+	>=x11-libs/libxkbcommon-0.5.0
+	>=x11-libs/pixman-0.25.2
+	x11-misc/xkeyboard-config
+	fbdev? (
+		>=sys-libs/mtdev-1.1.0
+		>=virtual/udev-136
+	)
+	colord? ( >=x11-misc/colord-0.1.27 )
+	drm? (
+		>=media-libs/mesa-17.1[gbm(+)]
+		>=sys-libs/mtdev-1.1.0
+		>=virtual/udev-136
+	)
+	editor? ( x11-libs/pango )
+	examples? ( x11-libs/pango )
+	gles2? (
+		media-libs/mesa[gles2,wayland]
+	)
+	pipewire? ( >=media-video/pipewire-0.3:= )
+	rdp? ( >=net-misc/freerdp-2.2.0:= )
+	remoting? (
+		media-libs/gstreamer:1.0
+		media-libs/gst-plugins-base:1.0
+	)
+	seatd? ( sys-auth/seatd:= )
+	systemd? (
+		sys-auth/pambase[systemd]
+		>=sys-apps/dbus-1.6
+		>=sys-apps/systemd-209[pam]
+	)
+	X? (
+		>=x11-libs/libxcb-1.9
+		x11-libs/libX11
+	)
+	xwayland? (
+		x11-base/xwayland
+		x11-libs/cairo[X,xcb(+)]
+		>=x11-libs/libxcb-1.9
+		x11-libs/libXcursor
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	${PYTHON_DEPS}
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use drm backend-drm)
+		-Dbackend-drm-screencast-vaapi=false
+		$(meson_use headless backend-headless)
+		$(meson_use rdp backend-rdp)
+		$(meson_use screen-sharing screenshare)
+		$(meson_use wayland-compositor backend-wayland)
+		$(meson_use X backend-x11)
+		$(meson_use fbdev deprecated-backend-fbdev)
+		-Dbackend-default=auto
+		$(meson_use gles2 renderer-gl)
+		$(meson_use xwayland)
+		$(meson_use seatd launcher-libseat)
+		$(meson_use systemd)
+		$(meson_use remoting)
+		$(meson_use pipewire)
+		$(meson_use desktop shell-desktop)
+		$(meson_use fullscreen shell-fullscreen)
+		$(meson_use ivi shell-ivi)
+		$(meson_use kiosk shell-kiosk)
+		$(meson_use lcms color-management-lcms)
+		$(meson_use colord color-management-colord)
+		$(meson_use systemd launcher-logind)
+		$(meson_use jpeg image-jpeg)
+		$(meson_use webp image-webp)
+		-Dtools=debug,info,terminal
+		$(meson_use examples demo-clients)
+		-Dsimple-clients=$(usex examples damage,dmabuf-v4l,im,shm,touch$(usex gles2 ,dmabuf-egl,egl "") "")
+		$(meson_use resize-optimization resize-pool)
+		-Dtest-junit-xml=false
+		-Dtest-gl-renderer=false
+		"${myconf[@]}"
+	)
+	meson_src_configure
+}
+
+src_test() {
+	xdg_environment_reset
+
+	# devices test usually fails.
+	# xwayland test can fail if X11 socket already exists.
+	cd "${BUILD_DIR}" || die
+	meson test $(meson test --list | grep -Exv "devices|xwayland") || die
+}
+
+src_install() {
+	meson_src_install
+	readme.gentoo_create_doc
+}