dev-ml/cryptokit: bump to 1.12 and switch to github

Package-Manager: Portage-2.3.6, Repoman-2.3.3

1 files changed, 52 insertions, 0 deletions

diff --git a/dev-ml/cryptokit/cryptokit-1.12.ebuild b/dev-ml/cryptokit/cryptokit-1.12.ebuild
new file mode 100644
index 000000000000..b871c219dcdd
--- /dev/null
+++ b/dev-ml/cryptokit/cryptokit-1.12.ebuild
@@ -0,0 +1,52 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI="5"
+
+OASIS_BUILD_DOCS=1
+OASIS_BUILD_TESTS=1
+
+inherit oasis versionator
+
+DESCRIPTION="Cryptographic primitives library for Objective Caml"
+HOMEPAGE="https://github.com/xavierleroy/cryptokit"
+SRC_URI="https://github.com/xavierleroy/cryptokit/archive/release$(replace_all_version_separators '').tar.gz -> ${P}.tar.gz"
+LICENSE="LGPL-2"
+SLOT="0/${PV}"
+KEYWORDS="~amd64 ~x86-fbsd"
+IUSE="zlib"
+
+DEPEND="zlib? ( >=sys-libs/zlib-1.1 )
+	dev-ml/zarith:="
+RDEPEND="${DEPEND}"
+
+DOCS=( "Changes" "README.txt" "AUTHORS.txt" )
+REQUIRED_USE="test? ( ocamlopt )"
+
+S="${WORKDIR}/${PN}-release$(replace_all_version_separators '')"
+
+src_configure() {
+	oasis_configure_opts="$(use_enable zlib)" \
+		oasis_src_configure
+}
+
+pkg_postinst() {
+	elog ""
+	elog "This library uses the /dev/random device to generate "
+	elog "random data and RSA keys.  The device should either be"
+	elog "built into the kernel or provided as a module. An"
+	elog "alternative is to use the Entropy Gathering Daemon"
+	elog "(http://egd.sourceforge.net).  Please note that the"
+	elog "remainder of the library will still work even in the"
+	elog "absence of a one of these sources of randomness."
+	elog ""
+}
+
+src_test() {
+	echo ""
+	einfo "You must have either /dev/random or the Entropy Gathering"
+	einfo "Daemon (EGD) for this test to succeed!"
+	echo ""
+
+	oasis_src_test
+}