dev-python/astropy: version bump

Package-Manager: Portage-2.3.5, Repoman-2.3.2

1 files changed, 93 insertions, 0 deletions

diff --git a/dev-python/astropy/astropy-1.3.3.ebuild b/dev-python/astropy/astropy-1.3.3.ebuild
new file mode 100644
index 000000000000..923ff494b4ba
--- /dev/null
+++ b/dev-python/astropy/astropy-1.3.3.ebuild
@@ -0,0 +1,93 @@
+# Copyright 1999-2017 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=6
+
+PYTHON_COMPAT=( python2_7 python3_{4,5,6} )
+
+inherit distutils-r1 xdg-utils
+
+DESCRIPTION="Core functionality for performing astrophysics with Python"
+HOMEPAGE="http://astropy.org/"
+SRC_URI="mirror://pypi/${PN:0:1}/${PN}/${P}.tar.gz"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~x86 ~amd64-linux ~x86-linux"
+IUSE="doc test"
+
+RDEPEND="
+	dev-libs/expat:0=
+	dev-python/configobj[${PYTHON_USEDEP}]
+	>=dev-python/numpy-1.10[${PYTHON_USEDEP}]
+	dev-python/ply[${PYTHON_USEDEP}]
+	dev-python/six[${PYTHON_USEDEP}]
+	>=sci-astronomy/erfa-1.3:0=
+	>=sci-astronomy/wcslib-5:0=
+	>=sci-libs/cfitsio-3.410:0=
+	sys-libs/zlib:0="
+DEPEND="${RDEPEND}
+	dev-python/astropy-helpers[${PYTHON_USEDEP}]
+	dev-python/cython[${PYTHON_USEDEP}]
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	virtual/pkgconfig
+	doc? (
+		media-gfx/graphviz
+		dev-libs/libxml2[${PYTHON_USEDEP}]
+		dev-python/h5py[${PYTHON_USEDEP}]
+		dev-python/jplephem[${PYTHON_USEDEP}]
+		dev-python/matplotlib[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},jpeg]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/sphinx-gallery[${PYTHON_USEDEP}]
+		sci-libs/scipy[${PYTHON_USEDEP}]
+	)
+	test? (
+		dev-libs/libxml2[${PYTHON_USEDEP}]
+		dev-python/pillow[${PYTHON_USEDEP},jpeg]
+		dev-python/pytest[${PYTHON_USEDEP}]
+		dev-python/pytest-mpl[${PYTHON_USEDEP}]
+		dev-python/h5py[${PYTHON_USEDEP}]
+		sci-libs/scipy[${PYTHON_USEDEP}]
+	)"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.3.3-mark-known-failures.patch
+	"${FILESDIR}"/${PN}-1.3.3-external-python-pkgs.patch
+)
+
+python_prepare_all() {
+	export mydistutilsargs="--offline"
+	export ASTROPY_USE_SYSTEM_PYTEST=True
+	#rm -r ${PN}_helpers || die
+	cp "${FILESDIR}"/astropy-ply.py astropy/extern/ply.py || die
+	rm -r cextern/{expat,erfa,cfitsio,wcslib} || die
+	sed -i -e '/auto_use/s/True/False/' setup.cfg || die
+	cat >> setup.cfg <<-EOF
+	[build]
+	use_system_libraries=1
+	EOF
+	xdg_environment_reset
+	distutils-r1_python_prepare_all
+}
+
+python_compile_all() {
+	if use doc; then
+		mkdir -p examples
+		touch examples/README.txt || die
+		python_setup
+		VARTEXFONTS="${T}"/fonts \
+			MPLCONFIGDIR="${BUILD_DIR}" \
+			PYTHONPATH="${BUILD_DIR}"/lib \
+			esetup.py build_docs --no-intersphinx
+	fi
+}
+
+python_test() {
+	esetup.py test
+}
+
+python_install_all() {
+	use doc && local HTML_DOCS=( docs/_build/html/. )
+	distutils-r1_python_install_all
+}