dev-python/backports-unittest-mock: bump to 1.4

Package-Manager: Portage-2.3.42, Repoman-2.3.9

2 files changed, 62 insertions, 0 deletions

diff --git a/dev-python/backports-unittest-mock/Manifest b/dev-python/backports-unittest-mock/Manifest
index 563d643c1612..20a81ac90c07 100644
--- a/dev-python/backports-unittest-mock/Manifest
+++ b/dev-python/backports-unittest-mock/Manifest
@@ -1,2 +1,3 @@
 DIST backports.unittest_mock-1.2.1.tar.gz 4580 BLAKE2B c935c378bae1f39e0658f4be027bcdbc13ecad6aeae93ca46ca314378f3c0462ea95b7b36daebdafd0577269520adb51a9f4cb7e74e9ab22c1bb6891d06c2384 SHA512 36218fe1117d62cc1aeea576c6220be7b8dd76b800776001756d157528ff7760791c513751a221ba84790c5b60b8ce62ab2ef17f4d359dd026211dc9c5cbcd5e
 DIST backports.unittest_mock-1.3.tar.gz 4687 BLAKE2B a01712eaf5cb32d7da803aa9034f68508faa4d8db8d6f6eb02e20cb9f42c4e6bda3b409a0e2f676b6b7782f16d78877da6f093af6ac1f1deb100b19969570787 SHA512 71741db5c2e43beac8c72dbffa0efd4bbae140177f56c3b2bca3e13a3aebd8a418b5ad7654421899980f73b8dbfb3b02d85d2dfcd7b3827047fa6ba84a8dcfff
+DIST backports.unittest_mock-1.4.tar.gz 6034 BLAKE2B c347f1d45c610701b605cb75304f93c8fc7a8534e2c14efb4600a7c5cdbcff02e0534dbf572ac248d17dbc161dcabd8448941d8340a71734f29ff3294c8210f1 SHA512 ad19eba7c221fbb97ba710cbe96aa26de74ad8c70ea7b794d8dcad3dc86a55a45d36f542ad829fb8c4bcf09c772cf64532dabf337b40bf87c7b29e13236484a9
diff --git a/dev-python/backports-unittest-mock/backports-unittest-mock-1.4.ebuild b/dev-python/backports-unittest-mock/backports-unittest-mock-1.4.ebuild
new file mode 100644
index 000000000000..63a89653734a
--- /dev/null
+++ b/dev-python/backports-unittest-mock/backports-unittest-mock-1.4.ebuild
@@ -0,0 +1,61 @@
+# Copyright 1999-2018 Gentoo Foundation
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=7
+
+# It is the developer's intention that backports.unittest_mock will be
+# used even for Python 3: https://github.com/jaraco/jaraco.timing/pull/1
+PYTHON_COMPAT=( pypy{,3} python{2_7,3_{4,5,6}} )
+
+inherit distutils-r1
+
+MY_PN="${PN/-/.}"
+MY_PN="${MY_PN//-/_}"
+DESCRIPTION="Backport of unittest.mock"
+HOMEPAGE="https://github.com/jaraco/backports.unittest_mock"
+SRC_URI="mirror://pypi/${PN:0:1}/${MY_PN}/${MY_PN}-${PV}.tar.gz"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-fbsd"
+IUSE="doc test"
+
+RDEPEND="
+	dev-python/backports[${PYTHON_USEDEP}]
+	dev-python/mock[${PYTHON_USEDEP}]
+"
+DEPEND="
+	dev-python/setuptools[${PYTHON_USEDEP}]
+	>=dev-python/setuptools_scm-1.15.0[${PYTHON_USEDEP}]
+	doc? (
+		>=dev-python/jaraco-packaging-3.2[${PYTHON_USEDEP}]
+		>=dev-python/rst-linker-1.9[${PYTHON_USEDEP}]
+		>=dev-python/sphinx-1.5.2[${PYTHON_USEDEP}]
+	)
+	test? (
+		${RDEPEND}
+		>=dev-python/pytest-2.8[${PYTHON_USEDEP}]
+	)
+"
+
+S="${WORKDIR}/${MY_PN}-${PV}"
+
+python_compile_all() {
+	if use doc; then
+		cd docs || die
+		sphinx-build . _build/html || die
+		HTML_DOCS=( docs/_build/html/. )
+	fi
+}
+
+python_test() {
+	# Override pytest options to skip flake8
+	py.test -v --override-ini="addopts=--doctest-modules" \
+		|| die "tests failed with ${EPYTHON}"
+}
+
+python_install() {
+	# avoid a collision with dev-python/backports
+	rm "${BUILD_DIR}"/lib/backports/__init__.py || die
+	distutils-r1_python_install --skip-build
+}